한계 세율을 계산하는 Web Form 생성
세금 관련 계산은 하나의 Web Form에 효율적으로 임베드하기에 너무 복잡한 경우가 많습니다. AskFunction을 사용하면 쉽고 직관적으로 계산을 표현할 수 있습니다.
In[1]:=
CloudDeploy[AskFunction[Module[{bracket, tax, income},
bracket =
Ask[{"brackets",
"What is your marital status?"} -> {"Married filing jointly" \
-> {18550, 75300, 151900, 231450, 413350, 466950},
"Single" -> {9275, 37650, 91150, 190150, 413350, 415050},
"Head of household" -> {13250, 50400, 130150, 210800, 413350,
441000},
"Married filing separately" -> {9275, 37650, 75950, 115725,
206675, 233475}}];
income =
Ask[{"income", "What was your income in 2015"} ->
Restricted["Number", {0, Infinity}]];
tax = Integrate[
Piecewise[{{.10 , 0 <= x <= bracket[[1]]}, {.15,
bracket[[1]] < x <= bracket[[2]]}, {.25,
bracket[[2]] < x <= bracket[[3]]}, {.28,
bracket[[3]] < x <= bracket[[4]]}, {.33,
bracket[[4]] < x <= bracket[[5]]}, {.35,
bracket[[5]] < x <= bracket[[6]]}, {.396, True}}], {x, 0,
income -
If[Ask[{"deps",
"Do you have any dependents?"} -> {"Yes" -> True,
"No" -> False}],
Ask[{"nodeps", "How many?"} ->
Restricted["Integer", {0, Infinity}]]* 4050, 0]}];
AskTemplateDisplay[
Column[{"You owe $" <> ToString[tax] <> " in taxes.",
"Your marginal tax rate is " <>
ToString[Round[100.*tax/#income, 0.1]] <> "%",
PieChart[{tax, income}]}] &]
]]]Out[1]=
이 예에서 볼 수 있듯이, 사용자가 원하는 프로그래밍 스타일을 결정할 수 있습니다. Module을 사용하여 계산 상태를 저장하거나 AskFunction을 사용하여 필요없는 질문을 제외시킬 수도 있습니다. 자신만의 스타일을 시험해 보세요.
