소비세 분석 API에 파일 업로드: Wolfram Language 11의 신기능

소비세 분석 API에 파일 업로드

URLRead를 사용하여 웹 서버에 파일을 업로드 할 수 있습니다.

온라인 상점에서 소비세 보고서를 분석하는 클라우드 오브젝트를 작성합니다.

전체 Wolfram 언어 입력 표시하기

In[1]:=

salesTaxReportAsText[rawdata_] := 
 With[{data = Map[extract, Rest[rawdata]]}, 
  StringReplace[
   ToString[
    Column[{"Order Report", 
      Grid[Join[{extract[First[rawdata]]}, 
        Map[format, 
         data, {2}], {{"Total:", format@Total[data[[All, 2]]], 
          format@Total[data[[All, 3]]]}}], Alignment -> Right], "", 
      "", Row[{"Total orders with no tax: ", 
        Total[Cases[data, {_, n_ /; n == 0, _}][[All, 3]]]}]}], 
    OutputForm], "\n\n" -> "\n"]]
extract[r_] := {First[r], r[[20]], r[[21]]}
format[x_] := Replace[x, {n_?NumericQ :> NumberForm[n, {Infinity, 2}]}]
orders = CloudDeploy[
  APIFunction[{"orders" -> "CSV"}, salesTaxReportAsText[#orders] &, 
   "Text"], "orders.api", Permissions -> "Public"]

Out[1]=

https://www.amazon.com/gp/b2b/reports를 열고 일정 기간 동안의 주문에 대한 보고서를 실행합니다. CSV 파일을 다운로드하거나 데모 데이터를 포함하는 파일을 생성합니다.

In[2]:=

Export["orders.csv", 
 "Order Date,Order ID,Payment Instrument Type,Website,Purchase Order \
Number,Ordering Customer Email,Shipment Date,Shipping Address \
Name,Shipping Address Street 1,Shipping Address Street 2,Shipping \
Address City,Shipping Address State,Shipping Address Zip,Order \
Status,Carrier Name & Tracking Number,Subtotal,Shipping Charge,Tax \
Before Promotions,Total Promotions,Tax Charged,Total Charged,Buyer \
Name,Group Name
 01/12/16,610,Visa - \
2493,Amazon.com,,customer@example.com,01/14/16,Alf B. Charlie,34 W \
Reindeer Tr,,Slaterock,KS,66083,Shipped,SUREPOST(1ZW532553XVFG),$36.\
11,$5.55,$0.00,$5.55,$0.00,$36.11,Alf B. Charlie,none
 01/22/16,111,Visa - \
2493,Amazon.com,,customer@example.com,01/23/16,Alf B. Charlie,34 W \
Reindeer Tr,,Slaterock,KS,66083,Shipped,QUICKSHIP(28zvW),$215.90,$3.\
86,$0.00,$3.86,$0.00,$215.90,Alf B. Charlie,none
 03/07/16,729,Visa - \
0832,Amazon.com,,customer@example.com,03/07/16,Alf B. Charlie,34 W \
Reindeer Tr,,Slaterock,KS,66083,Shipped,QUIKSHIP(29xcdQ),$48.95,$3.86,\
$4.28,$3.86,$4.28,$48.95,Alf B. Charlie,none
 08/25/16,729,Visa - \
0832,Amazon.com,,customer@example.com,08/25/16,Alf B. Charlie,34 W \
Reindeer Tr,,Slaterock,KS,66083,Shipped,QUIKSHIP(53fGkM),$69.48,$3.86,\
$6.08,$3.86,$6.08,$69.48,Alf B. Charlie,none", "Text"]

Out[2]=

보고서 API를 호출하여 순서 데이터 파일을 업로드하여 입력을 제공합니다.

In[3]:=

URLRead[HTTPRequest[
  orders, <|"Body" -> {"orders" -> File["orders.csv"]}|>], "Body"]

Out[3]=

Wolfram 언어™

소비세 분석 API에 파일 업로드

관련 예제