Wolfram Language™

Cifre y almacene un mapa del tesoro en la nube

Cualquier expresión de Wolfram Language puede ser cifrada.

Genere una clave simétrica fuerte derivada a partir de una contraseña secreta usando el método de Blowfish.

In[1]:=

skeletonKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[1]=

Cifre la ubicación del mensaje, almacénelo en un GeoMarker y visualícelo usando GeoGraphics, usando la clave generada.

In[2]:=

treasureMap = GeoGraphics[{GeoMarker[GeoPosition[{15.9429, -86.5031}], Text[Style["x", FontFamily -> "Bradley Hand", FontSize -> 24]]]}, FrameLabel -> "Where the Gold is Buried", Frame -> True, ImageSize -> 300, GeoBackground -> "StreetMapNoLabels"]

Out[2]=

In[3]:=

hiddenTreasure = Encrypt[skeletonKey, treasureMap]

Out[3]=

Ahora que los datos han sido cifrados de forma segura usando una clave local, cargue el mapa a Wolfram Cloud.

In[4]:=

stowed = CloudPut[hiddenTreasure]

Out[4]=

Con el fin de cubrir los rastros, deseche el mapa original y la clave usando Clear.

In[5]:=

Clear[hiddenTreasure]

In[6]:=

Clear[skeletonKey]

Dado que la clave fue derivada usando una contraseña, usted puede crear una nueva clave usando la entrada original.

In[7]:=

newKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[7]=

La nueva clave ahora puede ser usada para referirse al mapa implementado en la nube.

In[8]:=

reclaimedMap = Decrypt[newKey, CloudGet[stowed]]

Out[8]=

Extraiga la ubicación del tesoro.

In[9]:=

treasureLocation = reclaimedMap[[3, 2]]

Out[9]=

Pregunte por direcciones de conducir.

In[10]:=

TravelDirections[{$GeoLocation, treasureLocation}]

Out[10]=

Dado que no hay una ruta de manejo al tesoro, calcule su distancia usando GeoDistance.

In[11]:=

GeoDistance[$GeoLocation, treasureLocation]

Out[11]=

Dada la distancia, ubique el aeropuerto más cercano al tesoro.

In[12]:=

airport = First[GeoNearest["Airport", treasureLocation]]

Out[12]=

La distancia desde dicho aeropuerto al tesoro.

In[13]:=

GeoDistance[airport, treasureLocation]

Out[13]=