Wolfram Language™

Chiffrez et stockez une carte de trésor en cloud

Toute expression du Wolfram Language peut être chiffrée.

Générez une clé symétrique forte dérivée d'un mot de passe secret en utilisant la méthode de Blowfish.

In[1]:=

skeletonKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[1]=

Chiffrez le lieu du message, stockez en un GeoMarker et visualisez-le en utilisant GeoGraphics, utilisant la clé générée.

In[2]:=

treasureMap = GeoGraphics[{GeoMarker[GeoPosition[{15.9429, -86.5031}], Text[Style["x", FontFamily -> "Bradley Hand", FontSize -> 24]]]}, FrameLabel -> "Where the Gold is Buried", Frame -> True, ImageSize -> 300, GeoBackground -> "StreetMapNoLabels"]

Out[2]=

In[3]:=

hiddenTreasure = Encrypt[skeletonKey, treasureMap]

Out[3]=

Maintenant que les données sont chiffrées en toute sécurité en utilisant une clé locale, téléchargez la carte à Wolfram Cloud.

In[4]:=

stowed = CloudPut[hiddenTreasure]

Out[4]=

Afin de brouiller les pistes, jetez l'original en utilisant la carte et la clé Clear.

In[5]:=

Clear[hiddenTreasure]

In[6]:=

Clear[skeletonKey]

Étant donné que la clé a été calculée à l'aide d'un mot de passe, vous pouvez créer une nouvelle clé en utilisant l'entrée d'origine.

In[7]:=

newKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[7]=

La nouvelle clé peut maintenant être utilisée pour faire référence à la carte en cloud.

In[8]:=

reclaimedMap = Decrypt[newKey, CloudGet[stowed]]

Out[8]=

Extrayez l'emplacement du trésor.

In[9]:=

treasureLocation = reclaimedMap[[3, 2]]

Out[9]=

Demandez des directions.

In[10]:=

TravelDirections[{$GeoLocation, treasureLocation}]

Out[10]=

Comme il n'y a pas de voie de conduite au trésor, calculer la distance en utilisant ITS GeoDistance.

In[11]:=

GeoDistance[$GeoLocation, treasureLocation]

Out[11]=

Compte tenu de la distance, localisez l'aéroport le plus proche du trésor.

In[12]:=

airport = First[GeoNearest["Airport", treasureLocation]]

Out[12]=

La distance entre l'aéroport et le trésor.

In[13]:=

GeoDistance[airport, treasureLocation]

Out[13]=