Cifre e armazene um mapa do tesouro na nuvem

Qualquer expressão da Wolfram Linguagem pode ser cifrada.

Gere uma chave simétrica forte derivada de uma senha secreta usando o método Blowfish.

In[1]:=

skeletonKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[1]=

Cifre a localização do tesouro, armazenado em um GeoMarker e visualizado usando GeoGraphics, usando a chave gerada.

In[2]:=

treasureMap = GeoGraphics[{GeoMarker[GeoPosition[{15.9429, -86.5031}], Text[Style["x", FontFamily -> "Bradley Hand", FontSize -> 24]]]}, FrameLabel -> "Where the Gold is Buried", Frame -> True, ImageSize -> 300, GeoBackground -> "StreetMapNoLabels"]

Out[2]=

In[3]:=

hiddenTreasure = Encrypt[skeletonKey, treasureMap]

Out[3]=

Agora que os dados estão cifrados de forma segura usando uma chave local, carregue o mapa na Wolfram Cloud.

In[4]:=

stowed = CloudPut[hiddenTreasure]

Out[4]=

Para cobrir os rastros descarte o mapa original a chave usando Clear.

In[5]:=

Clear[hiddenTreasure]

In[6]:=

Clear[skeletonKey]

Como a chave foi derivada usando uma senha, você pode criar uma nova chave usando a entrada original.

In[7]:=

newKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[7]=

A nova chave agora pode ser usada para referir-se ao mapa implementado na nuvem.

In[8]:=

reclaimedMap = Decrypt[newKey, CloudGet[stowed]]

Out[8]=

Extraia a localização do tesouro.

In[9]:=

treasureLocation = reclaimedMap[[3, 2]]

Out[9]=

Pergunte por instruções de viagem.

In[10]:=

TravelDirections[{$GeoLocation, treasureLocation}]

Out[10]=

Como não existe uma rota de direção para o tesouro, calcule a distância usando GeoDistance.

In[11]:=

GeoDistance[$GeoLocation, treasureLocation]

Out[11]=

Dada a distância, localize o aeroporto mais próximo ao tesouro.

In[12]:=

airport = First[GeoNearest["Airport", treasureLocation]]

Out[12]=

A distância do aeroporto para o tesouro.

In[13]:=

GeoDistance[airport, treasureLocation]

Out[13]=