Язык Wolfram Language™

Шифровка и хранение карты сокровищ в облаке

Любое выражение на языке Wolfram Language может быть зашифровано.

Сгенерируйте сильный симметричный ключ, полученный из тайного пароля при помощи метода Blowfish.

In[1]:=

skeletonKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[1]=

Зашифруйте расположение сокровища, хранящегося в GeoMarker, и визуализируйте его, используя GeoGraphics, при помощи созданного ключа.

In[2]:=

treasureMap = GeoGraphics[{GeoMarker[GeoPosition[{15.9429, -86.5031}], Text[Style["x", FontFamily -> "Bradley Hand", FontSize -> 24]]]}, FrameLabel -> "Where the Gold is Buried", Frame -> True, ImageSize -> 300, GeoBackground -> "StreetMapNoLabels"]

Out[2]=

In[3]:=

hiddenTreasure = Encrypt[skeletonKey, treasureMap]

Out[3]=

Теперь, когда данные безопасно зашифрованы при помощи локального ключа, загрузите карту в облако Wolfram Cloud.

In[4]:=

stowed = CloudPut[hiddenTreasure]

Out[4]=

Для того, чтобы засекретить ценную информацию, удалите оригинальную карту и ключ, используя Clear.

In[5]:=

Clear[hiddenTreasure]

In[6]:=

Clear[skeletonKey]

Поскольку ключ был создан с использованием пароля, Вы можете создать новый ключ, используя оригинальный ввод.

In[7]:=

newKey = GenerateSymmetricKey["Avast ye!", Method -> "Blowfish"]

Out[7]=

Новый ключ может быть использован для ссылки на развёрнутую в облаке карту.

In[8]:=

reclaimedMap = Decrypt[newKey, CloudGet[stowed]]

Out[8]=

Извлеките расположение сокровища.

In[9]:=

treasureLocation = reclaimedMap[[3, 2]]

Out[9]=

Запросите маршрутный лист.

In[10]:=

TravelDirections[{$GeoLocation, treasureLocation}]

Out[10]=

Поскольку невозможно указать маршрут до сокровища, рассчитайте расстояние при помощи GeoDistance.

In[11]:=

GeoDistance[$GeoLocation, treasureLocation]

Out[11]=

Определите ближайший к сокровищу аэропорт с учетом данного расстояния.

In[12]:=

airport = First[GeoNearest["Airport", treasureLocation]]

Out[12]=

Расстояние от аэропорта до сокровища.

In[13]:=

GeoDistance[airport, treasureLocation]

Out[13]=