Часы обратного отсчета для нескольких пользователей
Создадим канал, который отображает часы обратного отсчета времени и зададим функцию, которая включает обратный отсчет.
In[1]:=
CreateChannel["Countdown",
HandlerFunctions ->
Association["MessageReceived" -> ((Countdown`$time = #Message) &)],
Initialization :>
CreateWindow[
DocumentNotebook[{Dynamic[
ClockGauge[$time, PlotTheme -> "Business"]]}],
WindowSize -> All, WindowElements -> {}, ShowCellBracket -> False,
Background -> Black, WindowFrameElements -> {"CloseBox"},
Selectable -> False, WindowTitle -> "Countdown",
CellContext -> "Countdown`"],
Permissions ->
Association["All" -> "Read", "Owner" -> {"Write", "Execute"}]]Out[1]=
In[2]:=
countdown[t_] :=
DynamicModule[{paused = True, lbl = "Pause", ii = t, up = None},
Row[{Button[Dynamic[If[paused, "Start", lbl]], paused = ! paused;
up = If[paused, None, UpdateInterval -> 1]],
Dynamic[Refresh[
If[ii >= 0 && ! paused,
" \[LongRightArrow] " <>
TextString[ChannelSend["Countdown", ii--]],
If[ii <= 0, up = None; lbl = "Done"]; ""], up,
TrackedSymbols :> {paused}]]}]]Подпишимся на данный канал.
In[3]:=
listener = ChannelListen["Countdown"]Out[3]=
Установим длительность времени для обратного отсчета (в сек.) и нажмем на кнопку, чтобы начать обратный отсчёт.
In[4]:=
countdown[20]Out[4]=
Часы обновляются пока работает обратный отсчет. Обновление можно приостановить, нажав на паузу.
Out[5]=
Другие пользователи могут пользоваться часами для обратного отсчёта, ссылаясь на данный канал в ChannelListen.
In[6]:=
$WolframID <> ":Countdown"Out[6]=
In[7]:=
$WolframID <> ":Countdown";
ChannelListen[%]Out[7]=
