Multi-User-Countdown-Uhr
Bestimmen Sie einen Kanal, der eine Countdown-Uhr anzeigt, sowie eine Funktion, die den Countdown steuert.
In[1]:=
CreateChannel["Countdown",
HandlerFunctions ->
Association["MessageReceived" -> ((Countdown`$time = #Message) &)],
Initialization :>
CreateWindow[
DocumentNotebook[{Dynamic[
ClockGauge[$time, PlotTheme -> "Business"]]}],
WindowSize -> All, WindowElements -> {}, ShowCellBracket -> False,
Background -> Black, WindowFrameElements -> {"CloseBox"},
Selectable -> False, WindowTitle -> "Countdown",
CellContext -> "Countdown`"],
Permissions ->
Association["All" -> "Read", "Owner" -> {"Write", "Execute"}]]Out[1]=
In[2]:=
countdown[t_] :=
DynamicModule[{paused = True, lbl = "Pause", ii = t, up = None},
Row[{Button[Dynamic[If[paused, "Start", lbl]], paused = ! paused;
up = If[paused, None, UpdateInterval -> 1]],
Dynamic[Refresh[
If[ii >= 0 && ! paused,
" \[LongRightArrow] " <>
TextString[ChannelSend["Countdown", ii--]],
If[ii <= 0, up = None; lbl = "Done"]; ""], up,
TrackedSymbols :> {paused}]]}]]Abonnieren Sie den Kanal.
In[3]:=
listener = ChannelListen["Countdown"]Out[3]=
Setzen Sie einen Countdown für eine bestimmte Sekundenzahl auf und drücken Sie den Startknopf.
In[4]:=
countdown[20]Out[4]=
Die Uhr wird aktualisiert, während der Countdown läuft, außer Sie unterbrechen.
Out[5]=
Andere User können Ihre Countdown-Uhr abonnieren, indem Sie Ihren Kanal in ChannelListen angeben.
In[6]:=
$WolframID <> ":Countdown"Out[6]=
In[7]:=
$WolframID <> ":Countdown";
ChannelListen[%]Out[7]=
