멀티 유저 카운트다운 시계
카운트다운 시계를 표시하는 채널과 카운트다운을 행하는 함수를 정의합니다.
In[1]:=
CreateChannel["Countdown",
HandlerFunctions ->
Association["MessageReceived" -> ((Countdown`$time = #Message) &)],
Initialization :>
CreateWindow[
DocumentNotebook[{Dynamic[
ClockGauge[$time, PlotTheme -> "Business"]]}],
WindowSize -> All, WindowElements -> {}, ShowCellBracket -> False,
Background -> Black, WindowFrameElements -> {"CloseBox"},
Selectable -> False, WindowTitle -> "Countdown",
CellContext -> "Countdown`"],
Permissions ->
Association["All" -> "Read", "Owner" -> {"Write", "Execute"}]]Out[1]=
In[2]:=
countdown[t_] :=
DynamicModule[{paused = True, lbl = "Pause", ii = t, up = None},
Row[{Button[Dynamic[If[paused, "Start", lbl]], paused = ! paused;
up = If[paused, None, UpdateInterval -> 1]],
Dynamic[Refresh[
If[ii >= 0 && ! paused,
" \[LongRightArrow] " <>
TextString[ChannelSend["Countdown", ii--]],
If[ii <= 0, up = None; lbl = "Done"]; ""], up,
TrackedSymbols :> {paused}]]}]]채널을 구독합니다.
In[3]:=
listener = ChannelListen["Countdown"]Out[3]=
일정 초 동안의 카운트다운을 설정하고 버튼을 클릭하여 시작합니다.
In[4]:=
countdown[20]Out[4]=
시계는 도중에 중단하지 않는 한, 카운트다운이 실행되는 동안 업데이트됩니다.
Out[5]=
ChannelListen에서 이 채널을 참조하여 다른 사용자도 이 카운트다운 시계를 구독 할 수 있습니다.
In[6]:=
$WolframID <> ":Countdown"Out[6]=
In[7]:=
$WolframID <> ":Countdown";
ChannelListen[%]Out[7]=
