Panorama de un viaje
Una imagen puede ser almacenada como un archivo que contenga tanto información de píxeles como meta-información. Usando Import, usted puede obtener tales meta-datos y descubrir información programable acerca del contexto de la imagen.
Importe y analice una colección de fotos tomadas durante una visita a Lisboa.
In[1]:=

files = Map[img \[Function] ExampleData[img, "FilePath"],
ExampleData[{"TestImageSet", "Lisbon2016"}]];
Vea un histograma de fechas de las imágenes.
In[2]:=

dates = Map[file \[Function] Import[file, "DateTime"], files];
In[3]:=

DateHistogram[dates, Quantity[1, "Hours"]]
Out[3]=

Vea un collage de vistas en miniatura.
In[4]:=

thumbnails =
ExampleData[{"TestImageSet", "Lisbon2016"}, "ThumbnailList"];
In[5]:=

ImageCollage[thumbnails, Method -> "Columns", ImagePadding -> 2]
Out[5]=

Presente las fotos en una línea de tiempo.
In[6]:=

TimelinePlot[MapThread[Labeled, {dates, thumbnails}],
PlotLayout -> "Vertical", ImageSize -> Medium]
Out[6]=

Agrupe toda la información en un conjunto de datos.
In[7]:=

gps = Map[file \[Function] Import[file, "GeoPosition"], files];
In[8]:=

ds = Dataset[
MapThread[
AssociationThread[{"Thumbnail", "DateTime",
"GeoPosition"} -> {##}] &, {thumbnails, dates, gps}]]
Out[8]=

Muestre las locaciones donde las imágenes fueron tomadas.
In[9]:=

GeoGraphics[
MapThread[
GeoMarker, {Normal[ds[All, "GeoPosition"]],
Normal[ds[All, "Thumbnail"]]}], ImageSize -> Medium]
Out[9]=
