Proposez un musée à visiter : Nouveautés de Wolfram Language 11

Proposez un musée à visiter

En analysant géographiquement les métadonnées d'une collection de photos touristiques, il est possible de suggérer d'autres sites touristiques dans la même zone, par exemple un musée.

In[1]:=

files = Map[img \[Function] ExampleData[img, "FilePath"], 
   ExampleData[{"TestImageSet", "Oxford2011"}]];
geopos = Map[file \[Function] Import[file, "GeoPosition"], files];

Calculez le barycentre des lieux où les photos ont été prises.

In[2]:=

geodata = 
 GeoPosition[{Mean@geopos[[ All, 1, 1]], Mean@geopos[[All, 1, 2]],  
   Mean@Cases[geopos, GeoPosition[{_, _, h_}] :> h]}]

Out[2]=

Trouvez le musée le plus proche.

In[3]:=

entMus = Quiet[First@GeoNearest["Museum", geodata]];

In[4]:=

geoMus = Quiet[FindGeoLocation@entMus];

Récupérez et rédigez des informations sur ce musée.

In[5]:=

mus = EntityValue[entMus, EntityProperty["Museum", "Name"]];
type = EntityValue[entMus, 
  EntityProperty["Museum", "MuseumTypes"]]; about = 
 WikipediaData[mus, "SummaryPlaintext"];
description = TextGrid[{
   {Style["MUSEUM TO VISIT", 15], SpanFromLeft},
   {Style["Name:", Bold], mus},
   {Style["Types:", Bold], 
    StringTake[ToString[type], {2, -2}]}, {Style["About:", Bold], 
    about}
    }, ItemSize -> {{4, 30}, Automatic}]

Out[5]=

Visualisez les informations de ce musée sous forme d'infobulle sur une carte des environs.

In[6]:=

tooltip = 
  Tooltip[GeoMarker[geoMus, Entity["Icon", "Museum"]], description];

In[7]:=

GeoGraphics[{Thick, Red, GeoDisk[geodata, Quantity[1000, "Meters"]], 
  tooltip}, "GeoRange" -> 1500, ImageSize -> Medium]

Out[7]=

Wolfram Language™

Proposez un musée à visiter

Exemples connexes