Wolfram Language

Photographie de calcul

Une visite en un clin d'œil

Une image peut être stockée sous la forme d'un fichier contenant à la fois le contenu des pixels et des méta-informations. En utilisant Import, vous pouvez obtenir ces métadonnées et découvrir des informations programmables sur le contexte d'une photo.

Importez et analysez une collection de photos prises lors d'une visite à Lisbonne.

In[1]:=
Click for copyable input
files = Map[img \[Function] ExampleData[img, "FilePath"], ExampleData[{"TestImageSet", "Lisbon2016"}]];

Affichez l'histogramme de la date des images.

In[2]:=
Click for copyable input
dates = Map[file \[Function] Import[file, "DateTime"], files];
In[3]:=
Click for copyable input
DateHistogram[dates, Quantity[1, "Hours"]]
Out[3]=

Affichez un collage de vignettes.

In[4]:=
Click for copyable input
thumbnails = ExampleData[{"TestImageSet", "Lisbon2016"}, "ThumbnailList"];
In[5]:=
Click for copyable input
ImageCollage[thumbnails, Method -> "Columns", ImagePadding -> 2]
Out[5]=

Présentez les photos sur une ligne chronologique..

In[6]:=
Click for copyable input
TimelinePlot[MapThread[Labeled, {dates, thumbnails}], PlotLayout -> "Vertical", ImageSize -> Medium]
Out[6]=

Rassemblez toutes les informations dans un jeu de données.

In[7]:=
Click for copyable input
gps = Map[file \[Function] Import[file, "GeoPosition"], files];
In[8]:=
Click for copyable input
ds = Dataset[ MapThread[ AssociationThread[{"Thumbnail", "DateTime", "GeoPosition"} -> {##}] &, {thumbnails, dates, gps}]]
Out[8]=

Affichez les lieux où les images ont été prises.

In[9]:=
Click for copyable input
GeoGraphics[ MapThread[ GeoMarker, {Normal[ds[All, "GeoPosition"]], Normal[ds[All, "Thumbnail"]]}], ImageSize -> Medium]
Out[9]=

Exemples connexes

de en es ja ko pt-br ru zh