Receptores de GPS y elevación

Los receptores de GPS miden las posiciones con respecto a una elipsoide achatado de referencia aproximando la superficie de la Tierra. Sin embargo, las elevaciones con respecto al elipsoidal no son de utilidad práctica directa: por ejemplo, la elevación de la superficie de un lago no es una constante en relación con el elipsoidal. Necesitamos convertirla a otra superficie de referencia, el geoide, el cual aproxima la media del nivel marino y la continua tierra adentro.

La elevación del geoide con respecto a la referencia elipsoidal es llamada "ondulación". Descargue los datos de ondulación en pies para los estados continuos de EE.UU.

In[1]:=

undulation = GeoElevationData[Entity["Country", "UnitedStates"], "Undulation"]

Out[1]=

El geoide está siempre en referencia con el elipsoidal en el área de EE.UU.

In[2]:=

MinMax[undulation]

Out[2]=

En particular, esta es una ondulación en la sede de Wolfram en Champaign.

In[3]:=

GeoElevationData[ GeoPosition[ Entity["City", {"Champaign", "Illinois", "UnitedStates"}]], "Undulation"]

Out[3]=

Descargue los datos para el mundo entero.

In[4]:=

undulation = GeoElevationData["World", "Undulation"]

Out[4]=

Represente como un mapa de relieve.

In[5]:=

image = ReliefPlot[undulation, DataReversed -> True, PlotRangePadding -> None, PlotLegends -> Automatic, MaxPlotPoints -> Infinity, Frame -> False]

Out[5]=

Utilice una proyección geográfica distinta.

In[6]:=

With[{bounds = {{-90, 90}, {-180, 180}}}, Legended[GeoGraphics[{GeoStyling[{"GeoImage", image[[1]]}, GeoRange -> bounds], GeoBoundsRegion[bounds]}, GeoRange -> bounds, GeoProjection -> "WinkelTripel", GeoGridLines -> True, ImageSize -> Medium], image[[2]]]]

Out[6]=