Konnektivität von US Counties

Konstruieren Sie den Konnektivitätsgraphen zwischen benachbarten US-Counties.

Ermitteln Sie die Liste aller Counties der zusammenhängenden US-Bundesstaaten.

In[1]:=

Length[counties = Flatten[EntityClass["AdministrativeDivision", "ContinentalUSStates"]["Subdivisions"]]]

Out[1]=

Fügen Sie den District of Columbia hinzu, der zu keinem der 48 zusammenhängenden kontinentalen Bundesstaaten gehört.

In[2]:=

AppendTo[counties, Entity["AdministrativeDivision", {"DistrictOfColumbia", "DistrictOfColumbia", "UnitedStates"}]];

Berechnen Sie für jedes County eine Liste der benachbarten Counties.

In[3]:=

bordering = EntityValue[counties, "BorderingCounties"];

Entfernen Sie jene Fälle, in denen keine Information zu angrenzenden Counties verfügbar ist.

In[4]:=

Length[missingpos = Position[bordering, _Missing]]

Out[4]=

In[5]:=

counties = Delete[counties, missingpos]; bordering = Delete[bordering, missingpos];

Konstruieren Sie die Ränder des Konnektivitätsgraphen der US-Counties.

In[6]:=

Length[edges = DeleteDuplicates[ Sort /@ Flatten[ MapThread[Thread[UndirectedEdge[##]] &, {counties, bordering}]]]]

Out[6]=

In[7]:=

Graph[counties, edges]

Out[7]=

Um eine etwas vertrautere Darstellung zu erzielen, downloaden Sie das geographische Zentrum jedes Counties.

In[8]:=

pos = GeoPosition[EntityValue[counties, "Position"]]

Out[8]=

Verwenden Sie die folgende kartographische Projektion.

In[9]:=

proj = {"LambertAzimuthal", "Centering" -> Entity["City", {"Topeka", "Kansas", "UnitedStates"}]};

In[10]:=

projpos = First@GeoGridPosition[pos, proj];

Dann sieht der Graph folgendermaßen aus.

In[11]:=

graph = Graph[counties, edges, VertexCoordinates -> projpos]

Out[11]=

Zwischen dem County San Francisco und Manhattan liegen mindestens 67 Counties, das Start- und Endcounty mit eingeschlossen.

In[12]:=

Length[path = FindShortestPath[graph, Entity[ "AdministrativeDivision", {"SanFranciscoCounty", "California", "UnitedStates"}], Entity[ "AdministrativeDivision", {"NewYorkCounty", "NewYork", "UnitedStates"}]]]

Out[12]=

In[13]:=

HighlightGraph[graph, PathGraph[path]]

Out[13]=