大盐湖的水波: Wolfram语言 11 的新功能

‹›

大盐湖的水波

通过使用 ImageMesh，这可以把图像片段转换成 BoundaryMeshRegion 对象. 这些网格区域使你可以利用其它领域的函数，比如有限元方法 (FEM).

下面来说明 FEM 方法，先确定犹他州大盐湖表面波的主要模式.

In[1]:=

img = EntityValue[Entity["Lake", "GreatSaltLake::yw8cf"], "Image"]

Out[1]=

用均值漂移滤波器规整图像.

In[2]:=

img2 = MeanShiftFilter[img, 3, 0.1]

Out[2]=

通过区域生长进行图像分割.

In[3]:=

mask = RegionBinarize[img2, \!\(\*
GraphicsBox[
TagBox[RasterBox[CompressedData["
1:eJzt1jEKwkAQQNFdK0uv4C1sLW0VD6AYxSZCFMRzCJ7XiF3SzFb7lf8ggUCK
D8MmM99f1sdJSuk67W/r3X3ZdbvHZtY/bNvr+dQ2h1V7a05Nt9h/Xnv21ytJ
kiRJkiRJkn5H7tVuGLMqzqo4q+KsiuNW8bKsimNWfbNwXVbF5Yzuqp0xZFUB
dBaui5kF/T5AsxJ1jNAsq0qgs3BlOSPDMrMLmvUBDcNnsbqov2x4FrWrdscA
NIu6SjCzoEOEZlGniF5Ta0eMmVXCqjjmCJlV5KzaDWNWxXGreFnMKvAIazeM
MUfIXEmtKsCs8hSWsCrOqjhmlSRJkiRJkvS/3tRrD1M=
"], {{0, 147}, {150, 
       0}}, {0, 1},
ColorFunction->GrayLevel],
BoxForm`ImageTag["Bit", ColorSpace -> Automatic, Interleaving -> None],
Selectable->False],
DefaultBaseStyle->"ImageGraphics",
ImageSizeRaw->{150, 147},
PlotRange->{{0, 150}, {0, 147}}]\), 1/5]

Out[3]=

提取湖水水面的 BoundaryMeshRegion 对象.

In[4]:=

\[ScriptCapitalR] = ImageMesh[mask]

Out[4]=

生成湖水水面的网格.

In[5]:=

\[CapitalOmega] = 
 TriangulateMesh[\[ScriptCapitalR], MaxCellMeasure -> 8]

Out[5]=

求解湖水水面的波动方程，先确定湖区内部的拉普拉斯算子的特征函数.

In[6]:=

\[ScriptCapitalL] = -\!\(
\*SubsuperscriptBox[\(\[Del]\), \({x, y}\), \(2\)]\(\[CurlyPhi][x, 
     y]\)\);

运用边界条件.

In[7]:=

\[ScriptCapitalB] = DirichletCondition[\[CurlyPhi][x, y] == 0, True];

生成特征值为 Λ 的特征函数 Φ 的标准正交基.

In[8]:=

{\[CapitalLambda], \[CapitalPhi]} = 
  NDEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]}, \[CurlyPhi][x,
     y], {x, y} \[Element] \[CapitalOmega], 64];

显示前六个振荡模式.

In[9]:=

GraphicsGrid[
 Partition[
  Table[ContourPlot[\[CapitalPhi][[
     k]], {x, y} \[Element] \[CapitalOmega], PlotRange -> All, 
    PlotLabel -> \[CapitalLambda][[k]], PlotTheme -> "Minimal"], {k, 
    6}],
  3
  ],
 ImageSize -> 512
 ]

Out[9]=

下面给出了衰减的振荡模式随时间的演化.

In[10]:=

\[CapitalTheta][\[Lambda]_, \[Xi]_, t_] = FullSimplify[
  DSolveValue[Join[{ \!\(
\*SubscriptBox[\(\[PartialD]\), \(t, 
         t\)]\(\(TraditionalForm\`\[CurlyTheta]\)[
         t]\)\) + \[Xi]  \!\(
\*SubscriptBox[\(\[PartialD]\), \(t\)]\(\(TraditionalForm\`\
\[CurlyTheta]\)[
          t]\)\) == -\[Lambda] \!\(TraditionalForm\`\[CurlyTheta]\)[
        t] }, {\!\(TraditionalForm\`\[CurlyTheta]\)[0] == 
      1, \[CurlyTheta]'[0] == 
      0} ], \!\(TraditionalForm\`\[CurlyTheta]\)[t], t],
  {\[Lambda] > 0, \[Xi] > 0, \[Xi]^2 < 4 \[Lambda], t \[Element] Reals}
  ]

Out[10]=

将一个初始扰动按特征函数展开，并令其随时间演进，从而获得波在整个湖面传播的仿真结果.

显示完整的 Wolfram 语言输入

In[11]:=

n = 64;
weights = Take[GaussianMatrix[{{n}, n/2}], -n - 1];
weights -= Last[weights];
weights = Most[weights];
weights *= 1/First[weights];
wave[t_] = (\[CapitalTheta][\[CapitalLambda], 0.005, 
      t] weights  (\[CapitalPhi] /. {x -> 50, 
        y -> 60} )) . \[CapitalPhi];
waveColors = (Blend[{{-0.01, Purple}, {-0.005, Blue}, {0., 
       Green}, {0.005, Orange}, {0.01, Yellow}}, #] &);
anim =
  Table[
   ContourPlot[
    wave[t], {x, y} \[Element] \[CapitalOmega],
    PlotRange -> {-0.01, 0.012}, 
    Contours -> Range[-0.01, 0.012, 0.0005],
    PlotTheme -> "Minimal",
    ColorFunctionScaling -> False, 
    ContourStyle -> None,
    ColorFunction -> waveColors
    ],
   {t, 0, 255, 1}
   ];
ListAnimate[anim]

播放动画

停止播放动画

Wolfram 语言™

大盐湖的水波

相关范例