Wolfram Language

Réseaux neuronaux

Apprenez le paramétrage d'une variété

Apprenez à paramétrer une variété le long de laquelle se trouvent les données d'entrée en utilisant un auto-encodeur, un réseau doté d'une couche de « goulot d'étranglement » qui apprend à reconstruire l'entrée d'origine.

Échantillonnez les données d'apprentissage d'une partie d'une variété bidimensionnelle synthétique.

In[1]:=
Click for copyable input
manifold = Table[AngleVector[{x, 0.9 Pi x}] + x/20*RandomVariate[NormalDistribution[], 2], {x, 0, 1, 0.001}]; plot = ListPlot[manifold, PlotStyle -> Orange]
Out[1]=

Créez un réseau avec une couche de « goulot d'étranglement » dans le but d'apprendre le paramétrage de la variété.

In[2]:=
Click for copyable input
net = NetChain[{25, Ramp, 1, 25, Ramp, 2}, "Input" -> 2]
Out[2]=

Créez un réseau de perte qui calcule une perte sur la base d'une « erreur de reconstruction », une mesure du degré auquel le réseau peut produire une sortie qui est identique à son entrée.

In[3]:=
Click for copyable input
lossNet = NetGraph[{net, MeanSquaredLossLayer[]}, {1 -> 2, NetPort["Input"] -> NetPort[2, "Target"]}]
Out[3]=

Entraînez le réseau de perte sur la variété et extrayez le réseau d'origine à partir du réseau de perte.

In[4]:=
Click for copyable input
lossNet = NetTrain[lossNet, <|"Input" -> manifold|>, BatchSize -> 4096]; trained = NetExtract[lossNet, 1];

Visualisez la façon dont le réseau projette des points arbitraires sur la variété.

In[5]:=
Click for copyable input
{{xmin, xmax}, {ymin, ymax}} = CoordinateBounds[manifold, .2]; Show[plot, StreamPlot[ trained[{x, y}] - {x, y}, {x, xmin, xmax}, {y, ymin, ymax}]]
Out[5]=

Divisez le réseau en un réseau « encodeur » et un réseau « décodeur » (l'encodeur paramétrise les points en utilisant une valeur scalaire unique, alors que le décodeur reconstruit le point à partir de ce paramétrage).

In[6]:=
Click for copyable input
decoder = Drop[trained, 3] encoder = Take[trained, 3]
Out[6]=
Out[6]=

Coloriez chaque point dans la variété d'origine par son paramétrage sous l'encodeur.

In[7]:=
Click for copyable input
ListPlot[Style[#, Hue[First[0.3 + encoder[#]]/3]] & /@ manifold]
Out[7]=

Obtenez la plage de paramétrage en appliquant l'encodeur sur la variété.

In[8]:=
Click for copyable input
{min, max} = MinMax[encoder[manifold]]
Out[8]=

Affichez la reconstruction sur cette plage avec la variété d'origine.

In[9]:=
Click for copyable input
Show[plot, ListLinePlot[Table[decoder[x], {x, min, max, .01}]]]
Out[9]=

Exemples connexes

de en es ja ko pt-br ru zh