Faites le suivi de la popularité des noms : Nouveautés de Wolfram Language 11

Faites le suivi de la popularité des noms

Obtenez les noms les plus populaires pour les filles et leur classement dans le temps.

In[1]:=

girls = SortBy[
  EntityList[
   EntityClass[
    "GivenName", {"Gender" -> "Female", 
     "Rank" -> Interval[{1, 10}]}]], #["Rank"] &]

Out[1]=

In[2]:=

ranksgirls = 
  Table[EntityValue[name, 
    Dated[EntityProperty["GivenName", "Rank"], All]], {name, girls}];

Tracez les classements des 50 dernières années sur une échelle logarithmique dont le sommet est le nom le plus populaire.

In[3]:=

DateListStepPlot[ranksgirls, 
 ScalingFunctions -> {-Log[#] &, Exp[-#] &}, PlotLegends -> girls, 
 PlotTheme -> "Business", ImageSize -> 475, 
 PlotRange -> {{DateObject[{1965}], DateObject[{2015}]}, All}]

Out[3]=

In[4]:=

boys = SortBy[
   EntityList[
    EntityClass[
     "GivenName", {"Gender" -> "Male", 
      "Rank" -> Interval[{1, 10}]}]], #["Rank"] &];

In[5]:=

ranksboys = 
  Table[EntityValue[name, 
    Dated[EntityProperty["GivenName", "Rank"], All]], {name, boys}];

Le classement des prénoms de garçons montre que certains prénoms ont une popularité constante au fil du temps.

In[6]:=

DateListStepPlot[ranksboys, 
 ScalingFunctions -> {-Log[#] &, Exp[-#] &}, PlotLegends -> boys, 
 PlotTheme -> "Business", ImageSize -> 475, 
 PlotRange -> {{DateObject[{1965}], DateObject[{2015}]}, All}]

Out[6]=