Wolfram Language™

Enumérez les structures de PCB et partagez-les via un EntityStore

Un polychlorobiphényle (PCB) est un composé organique dont la formule chimique est la suivante : . Les PCB étaient autrefois utilisés pour un certain nombre d'applications industrielles, notamment dans les transformateurs électriques. Nous illustrons ici la génération et le stockage de tous les polychlorobiphényles (PCB) possibles en tant qu'entités personnalisées dans un magasin d'entités.

ChemicalData contient déjà la structure du PCB, le diphényle (également souvent appelé « biphényle »).

In[1]:=

Entity["Chemical", "Biphenyl"]["ColorStructureDiagram"]

Out[1]=

ChemicalData contient également un congénère particulier de la molécule de PCB.

In[2]:=

Entity["Chemical", "PCB"][ EntityProperty["Chemical", "ColorStructureDiagram"]]

Out[2]=

La structure générique du PCB comporte 10 sites, indiqués ci-dessous par des X. Pour obtenir tous les dérivés monochlorés à décochlorés possibles (c'est-à-dire les congénères), il faut attacher des substituants chlorés à ces 10 sites de toutes les manières possibles. Ici, la structure générique en tant que représentation au format "MOL" est chargée à partir d'un CloudObject prédéfini.

In[3]:=

molString = CloudGet[CloudObject[ "https://www.wolframcloud.com/objects/user-722de5bb-ef39-4cbd-\ 999d-546c888892d6/PCB_scaffold"]][[2]];

In[4]:=

ImportString[molString, "MOL"]

Out[4]=

Avec un peu de théorie des groupes, toutes les structures de PCB peuvent être énumérées. La propriété de symétrie essentielle de l'ensemble de la structure, exprimée sous la forme d'un groupe de permutation, est le point de départ.

In[5]:=

biphenylSymmetry = PermutationGroup[{Cycles[{{6, 10}, {7, 9}}], Cycles[{{1, 5}, {2, 4}}], Cycles[{{1, 6}, {2, 7}, {3, 8}, {4, 9}, {5, 10}}]}];

Formez le polynôme de l'indice de cycle à partir du théorème de comptage de Pólya et manipulez ses coefficients pour obtenir un décompte de 210 congénères (y compris la structure d'hydrocarbure non substituée, qui n'est pas un PCB en raison de l'absence de chlore).

In[6]:=

ci = Factor[ CycleIndexPolynomial[biphenylSymmetry, Array[Subscript[x, #] &, 4]]]

Out[6]=

In[7]:=

Total[CoefficientList[Expand[ci /. Subscript[x, i_] -> (x^i + 1)], x]]

Out[7]=

Après avoir renommé les positions des locants à l'aide de simples remplacements de chaînes de caractères, les 209 noms conformes à l'UICPA sont générés.

In[8]:=

conPos = Flatten[(PositionIndex /@ First /@ GroupOrbits[biphenylSymmetry, Permutations[#], Permute]) & /@ (LowerTriangularize[ ConstantArray["Cl", {10, 10}]] /. 0 -> "H")] /. Thread[Range[10] -> {"2", "3", "4", "5", "6", "2'", "3'", "4'", "5'", "6'"}];

In[9]:=

(names = Flatten[{StringJoin[Riffle[Sort[#["Cl"]], ","]] <> "-" <> (Length[#["Cl"]] /. Thread[Range[10] -> {"Chloro", "Dichloro", "Trichloro", "Tetrachloro", "Pentachloro", "Hexachloro", "Heptachloro", "Octachloro", "Nonachloro", "Decachloro"}]) <> "biphenyl"} & /@ conPos] /. "2,2',3,3',4,4',5,5',6,6'-Decachlorobiphenyl" -> "Decachlorobiphenyl") // Short

Out[9]//Short=

De la même manière, générez de manière exhaustive toutes les structures des congénères.

In[10]:=

PCBstruct = ImportString[ StringReplacePart[molString, #, StringPosition[molString, "X"]], "MOL"] & /@ Flatten[(First /@ GroupOrbits[biphenylSymmetry, Permutations[#], Permute]) & /@ (LowerTriangularize[ ConstantArray["Cl", {10, 10}]] /. 0 -> "H"), 1];

In[11]:=

TextGrid[Transpose[{names, PCBstruct}] // Take[#, 2] &, Dividers -> All]

Out[11]=

Pour inclure des propriétés plus détaillées des congénères, importez le PCB en tant que jeu de données à partir d'un CloudObject précalculé.

In[12]:=

imp = CloudGet[CloudObject[ "https://www.wolframcloud.com/objects/user-722de5bb-ef39-4cbd-\ 999d-546c888892d6/PCB_congeners_propertylist"]];

In[13]:=

TextGrid[Take[imp, 5], Background -> {Automatic, {LightBlue}}, Dividers -> All]

Out[13]=

Combinez les données importées avec les structures et les noms calculés précédemment.

In[14]:=

TextGrid[(PCBdata = SortBy[MapThread[ Flatten[{#1, Pick[imp[[3 ;;]], imp[[3 ;;, 1]], #2]}] &, {PCBstruct, names}], #[[3]] &]) // Take[#, 2] &, Dividers -> All]

Out[14]=

Créez un magasin d'entités personnalisé pour ces structures PCB.

In[15]:=

entities = Association @@ Map["PCB" <> ToString[#[[3]]] -> <| "ColorStructureDiagram" -> #[[1]], "IUPACName" -> #[[2]], "CASNumber" -> #[[4]], "BZNumber" -> #[[3]], "PCBDescriptors" -> #[[5]], "Label" -> "PCB-BZ#" <> ToString[#[[3]]] |> &, PCBdata];

In[16]:=

properties = <| "ColorStructureDiagram" -> <|"Label" -> "structure diagram"|>, "IUPACName" -> <|"Label" -> "IUPAC name"|>, "CASNumber" -> <|"Label" -> "CAS number"|>, "BZNumber" -> <|"Label" -> "Ballschmiter-Zell number"|>, "PCBDescriptors" -> <|"Label" -> "congener shorthand notation"|>, "Toxicity" -> <| "DefaultFunction" -> Function[e, If[StringCount[e["PCBDescriptors"], ","] == 3, "highly toxic", "toxic"]], "Label" -> "dioxin-like toxicity" |>, "NumberOfChlorineSubstituents" -> <| "DefaultFunction" -> Function[e, If[e["IUPACName"] == "Decachlorobiphenyl", 10, StringCount[e["IUPACName"], NumberString]]], "Label" -> "number of chlorine substituents" |> |>;

In[17]:=

classes = <| "CoplanarPCB" -> <| "Entities" -> {"IUPACName" -> (StringFreeQ[ "2" | "2'" | "6" | "6'" | "Deca"])}, "Label" -> "Coplanar or non-ortho PCBs" |>, "NoncoplanarPCB" -> <| "Entities" -> {"IUPACName" -> StringContainsQ["2" | "2'" | "6" | "6'"]}, "Label" -> "Noncoplanar PCBs" |> |>;

In[18]:=

store = EntityStore[ "PCB" -> <| "Label" -> "polychlorinated biphenyl", "LabelPlural" -> "polychlorinated biphenyls", "Entities" -> entities, "Properties" -> properties, "EntityClasses" -> classes |>]

Out[18]=

Enregistrez le magasin pour cette session.

In[19]:=

PrependTo[$EntityStores, store];

Testez le magasin d'entités en appelant une entité aléatoire.

In[20]:=

EntityValue[RandomEntity["PCB"], "PropertyAssociation"]

Out[20]=

Afin de rendre toutes les entités personnalisées disponibles dans les sessions futures ou pour les applications publiques, écrivez le magasin d'entités dans un CloudObject.

In[21]:=

CloudPut[store, "PCB_entity_store", Permissions -> "Public"]

Out[21]=