Запрос в базу данных Wolfram при использовании естественного языка: Новое в системе Wolfram Language 11

Запрос в базу данных Wolfram при использовании естественного языка

Создайте функцию для поиска песен по исполнителю и названию альбома и сгенерируйте таблицу с информацией о композиторе.

In[1]:=

songLookup[act_, album_] := 
 Module[{actEntity, albumEntity, songs, composers},
  actEntity = Interpreter["MusicAct"][act];
  albumEntity = Interpreter["MusicAlbum"][album];
  songs = 
   EntityList[
    EntityClass[
     "MusicWork", {"AssociatedMusicActs" -> actEntity, 
      "AssociatedMusicAlbums" -> albumEntity}]];
  composers = EntityValue[songs, "Composers"];
  Column[{albumEntity["Image"], 
    Grid[Transpose[{songs, composers}], 
     Background -> {Automatic, {{LightOrange, White}}}]}]]

Разверните простую грамматику, которая использует встроенные интерпретаторы для определения понятий типа "MusicAct" и "MusicAlbum".

In[2]:=

songGrammar = CloudDeploy[
  GrammarRules[
   {AnyOrder[
      OptionalElement[
       FixedOrder[
        "songs" | "titles" | "tracks" | "tunes" | "recordings", 
        OptionalElement["by" | "from"]]],
      act : GrammarToken["MusicAct"],
      FixedOrder[OptionalElement["from" | "on"],
       album : GrammarToken["MusicAlbum"]]
      ] :> songLookup[act, album]}]]

Out[3]=