信号导数近似
用 MovingMap 近似计算来自不规则采样连续时间序列的信号的导数.
In[1]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_46.png)
ts = TimeSeries[
Table[{t, EllipticTheta[1, t, 0.3]}, {t,
Join[{0.}, RandomReal[{0, 2 Pi}, 254], {2. Pi}]}]]
Out[1]=
![](assets.zh/approximate-signal-derivative/O_24.png)
In[2]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_47.png)
RegularlySampledQ[ts]
Out[2]=
![](assets.zh/approximate-signal-derivative/O_25.png)
In[3]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_48.png)
ListPlot[ts, PlotTheme -> "Detailed"]
Out[3]=
![](assets.zh/approximate-signal-derivative/O_26.png)
使用每个滑动窗口边界的值和时间来计算差商.
In[4]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_49.png)
quotient[values_, times_] :=
First[Differences[values]/Differences[times]]
In[5]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_50.png)
mm = MovingMap[quotient[#BoundaryValues, #BoundaryTimes] &,
ts, {.01, Right}]
Out[5]=
![](assets.zh/approximate-signal-derivative/O_27.png)
与导数的理论结果比较.
In[6]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_51.png)
prime = D[EllipticTheta[1, t, 0.3], t]
Out[6]=
![](assets.zh/approximate-signal-derivative/O_28.png)
In[7]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_52.png)
Show[Plot[prime, {t, 0, 2 \[Pi]}, PlotStyle -> Thick,
PlotTheme -> "Detailed", PlotLegends -> None],
ListPlot[mm, PlotStyle -> Red]]
Out[7]=
![](assets.zh/approximate-signal-derivative/O_29.png)
使用 MovingMap,同时用 Line 代替上面的商函数来产生一个近似于原时间序列的割线图.
In[8]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_53.png)
line[yvals_, xvals_] := Line[Transpose[{xvals, yvals}]];
In[9]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_54.png)
lines = MovingMap[ line[#BoundaryValues, #BoundaryTimes] &,
ts, {1.3, Right, {0, 2. \[Pi], .1}}];
In[10]:=
![Click for copyable input](assets.zh/approximate-signal-derivative/In_55.png)
Graphics[{Black, lines["Values"]}]
Out[10]=
![](assets.zh/approximate-signal-derivative/O_30.png)