Bemannte Raumfahrt

MannedSpaceMissionData liefert historische und aktuelle Informationen über die Erkundung des Alls durch den Menschen.

In[1]:=

missions = MannedSpaceMissionData[];

Sie können eine EventSeries basierend auf dem Datums des Starts der Missionen erstellen, wobei Vektorwerte die Missions-Entität und die Dauer jeder Mission speichern.

In[2]:=

data = DeleteMissing[ MannedSpaceMissionData[ missions, {"LaunchDate", "Entity", "MissionDuration"}], 1, 2];

In[3]:=

es = EventSeries[data[[All, {2, 3}]], {data[[All, 1]]}]

Out[3]=

TimelinePlot der Zeitstempel zeigt die fast stetigen Abstände der bemannten Raummissionen seit 1961.

In[4]:=

TimelinePlot[es["Dates"]]

Out[4]=

Um die Dauer der Missionen zu ananlysieren, extrahieren Sie die zweite Komponente der ursprünglichen Ereignisreihe und konvertieren Sie die Werte in Stunden.

In[5]:=

durations = UnitConvert[es["PathComponent", 2], "Hours"]

Out[5]=

Kurze Missionen kommen am häufigsten vor.

In[6]:=

Histogram[durations, Quantity[{0, 6000, 500}, "Hours"], AxesLabel -> Automatic]

Out[6]=

In[7]:=

x1 = 250; x2 = 4500; line1 = {{es["FirstDate"], x1}, {es["LastDate"], x1}}; line2 = {{es["FirstDate"], x2}, {es["LastDate"], x2}}; opts = {Joined -> {False, True, True}, Filling -> {1 -> 0}, PlotLabels -> {None, Quantity[x1, "Hours"], UnitConvert[Quantity[N[x2, 4], "Hours"], "Days"]}};

In[8]:=

DateListPlot[{durations, line1, line2}, opts]

Out[8]=

Berechnen Sie deskriptive Statistik zur Dauer der Missionen. Beachten Sie, dass der Mittelwert und der Median weit auseinanderliegen, was ein Indiz für eine Long-Tail-Verteilung ist.

In[9]:=

stats = {Min, Max, Mean, Median}; convert := UnitConvert[N[#], MixedUnit[{"Months", "Days", "Hours", "Minutes"}]] &

In[10]:=

TableForm[Map[convert[#[durations]] &, stats], TableHeadings -> {stats}]

Out[10]//TableForm=

Die Gesamtzeit menschlicher Aufenthalte im All.

In[11]:=

UnitConvert[Total[durations], MixedUnit[{"Years", "Months", "Days", "Hours", "Minutes", "Seconds"}]]

Out[11]=