Wolfram Language

Processamento de séries temporais

Missões espaciais tripuladas

MannedSpaceMissionData possui informação histórica e atualizada sobre a exploração humana no espaço.

In[1]:=
Click for copyable input
missions = MannedSpaceMissionData[];

Você pode criar um EventSeries baseado na data de lançamento das missões com valores de vetor armazenando a missão como entidade e a duração de cada missão.

In[2]:=
Click for copyable input
data = DeleteMissing[ MannedSpaceMissionData[ missions, {"LaunchDate", "Entity", "MissionDuration"}], 1, 2];
In[3]:=
Click for copyable input
es = EventSeries[data[[All, {2, 3}]], {data[[All, 1]]}]
Out[3]=

O gráfico TimelinePlot de marcas de tempo mostra o intervalo quase contínuo das missões espaciais tripuladas desde 1961.

In[4]:=
Click for copyable input
TimelinePlot[es["Dates"]]
Out[4]=

Para analisar as durações das missões extraímos o segundo componente da série de evento original e convertemos os valores para horas.

In[5]:=
Click for copyable input
durations = UnitConvert[es["PathComponent", 2], "Hours"]
Out[5]=

As missões curtas são mais comuns.

In[6]:=
Click for copyable input
Histogram[durations, Quantity[{0, 6000, 500}, "Hours"], AxesLabel -> Automatic]
Out[6]=
mostre o input completo da Wolfram Language
In[7]:=
Click for copyable input
x1 = 250; x2 = 4500; line1 = {{es["FirstDate"], x1}, {es["LastDate"], x1}}; line2 = {{es["FirstDate"], x2}, {es["LastDate"], x2}}; opts = {Joined -> {False, True, True}, Filling -> {1 -> 0}, PlotLabels -> {None, Quantity[x1, "Hours"], UnitConvert[Quantity[N[x2, 4], "Hours"], "Days"]}};
In[8]:=
Click for copyable input
DateListPlot[{durations, line1, line2}, opts]
Out[8]=

Calcule algumas estatísticas descritivas das durações das missões. Note que a média e a mediana estão longe uma da outra, indicando uma distribuição de cauda longa.

In[9]:=
Click for copyable input
stats = {Min, Max, Mean, Median}; convert := UnitConvert[N[#], MixedUnit[{"Months", "Days", "Hours", "Minutes"}]] &
In[10]:=
Click for copyable input
TableForm[Map[convert[#[durations]] &, stats], TableHeadings -> {stats}]
Out[10]//TableForm=

O tempo total que um humano ficou no espaço.

In[11]:=
Click for copyable input
UnitConvert[Total[durations], MixedUnit[{"Years", "Months", "Days", "Hours", "Minutes", "Seconds"}]]
Out[11]=

Exemplos Relacionados

de en es fr ja ko ru zh