Wolfram Language

Verarbeitung von Zeitreihen

Saisonale Muster visualisieren

Vergleichen Sie den saisonalen Niederschlag an einem Ort im Mittleren Westen und im Südwesten der USA.

WeatherData liefert den kumulierten Niederschlag in cm.

In[1]:=
Click for copyable input
start = {1999, 1, 1}; end = {2015, 12, 31};
In[2]:=
Click for copyable input
getData[place_] := WeatherData[place, "TotalPrecipitation", {start, end, "Month"}]

Erstellen Sie eine TimeSeries des Niederschlags in Champaign, Illinois, und Phoenix, Arizona. Legen Sie eine MissingDataMethod fest, um mit Interpolation fehlende Daten aufzufüllen.

In[3]:=
Click for copyable input
makeTS[place_] := TimeSeries[getData[place], MissingDataMethod -> "Interpolation"]
In[4]:=
Click for copyable input
tsIL = makeTS[ Entity["City", {"Champaign", "Illinois", "UnitedStates"}]]
Out[4]=
In[5]:=
Click for copyable input
tsAZ = makeTS[Entity["City", {"Phoenix", "Arizona", "UnitedStates"}]]
Out[5]=

Erstellen Sie WeightedData mit Niederschlagsmengen als Gewichtungen und plotten Sie DateHistogram mit dem Durchschnitt der Daten über die Gesamtzahl der Jahre.

In[6]:=
Click for copyable input
dataIL = WeightedData[tsIL["Dates"], tsIL["Values"]]; dataAZ = WeightedData[tsAZ["Dates"], tsAZ["Values"]];
In[7]:=
Click for copyable input
totalyears = (end[[1]] - start[[1]] + 1);
In[8]:=
Click for copyable input
avg := Function[{x, y}, y/totalyears]
In[9]:=
Click for copyable input
makeHistogram[data_, lab_] := DateHistogram[data, "Month", avg, DateReduction -> "Year", PlotRange -> {All, {-1, 9}}, AxesLabel -> "cm", PlotLabel -> lab]
In[10]:=
Click for copyable input
{makeHistogram[dataIL, "IL"], makeHistogram[dataAZ, "AZ"]}
Out[10]=

Verwandte Beispiele

en es fr ja ko pt-br ru zh