Arreglos de cantidades

QuantityArray permite el almacenaje y la manipulación eficiente de arreglos de objetos de Quantity y, por lo tanto, es ideal para el análisis de datos con unidades físicas. Continuando con la integración de cantidades en todo el sistema, varias funciones ahora comprenden o regresan objetos de QuantityArray.

Muestree objetos de QuantityDistribution.

In[1]:=

RandomVariate[ParetoDistribution[Quantity[500., "USDollars"], 4], 300]

Out[1]=

Un objeto de QuantityArray es equivalente a un arreglo normal de elementos de Quantity.

In[2]:=

RandomVariate[ParetoDistribution[Quantity[500., "USDollars"], 4], 300]; Normal[Take[%, 10]]

Out[2]=

Calcule o descargue arreglos de datos geográficos, tales como datos de elevación o campo magnético.

In[3]:=

GeoElevationData[Entity["Country", "UnitedStates"]]

Out[3]=

In[4]:=

GeomagneticModelData[ Entity["GeographicRegion", "Antarctica"], "Magnitude"]

Out[4]=

Manipule arreglos de ángulos de latitud y longitud.

In[5]:=

GeoElevationData[ Entity["Country", "UnitedStates"], "Undulation", GeoPosition]

Out[5]=

In[6]:=

GeoElevationData[ Entity["Country", "UnitedStates"], "Undulation", GeoPosition]; LatitudeLongitude[%]

Out[6]=

Obtenga un arreglo de datos para el componente vertical del campo gravitacional sobre China.

In[7]:=

data = GeogravityModelData[Entity["Country", "China"], "DownComponent"]

Out[7]=

Examine cómo el campo gravitacional difiere del valor estándar de 9.81 sobre dicha región.

In[8]:=

contourplot = ListContourPlot[data - Quantity[1, "StandardAccelerationOfGravity"], Frame -> False, PlotRangePadding -> 0, ColorFunction -> "SolarColors"]

Out[8]=

Superponga un gráfico de contorno sobre un mapa de China.

In[9]:=

Legended[GeoGraphics[{GeoStyling[{"GeoImage", contourplot}, Opacity[0.8]], Polygon[Entity["Country", "China"]]}, ImageSize -> 500, GeoRange -> Quantity[2200, "Kilometers"], GeoZoomLevel -> 5], BarLegend[{"SolarColors", MinMax@Flatten[QuantityMagnitude@data]}]]

Out[9]=