Wolfram Language™

Conversión al calendario maya

Identifique la época (o fecha de inicio) para el calendario de cuenta larga maya como una fecha juliana.

In[1]:=

epoch = JulianDate["Modified", DateObject[{-3114, 8, 11}, TimeZone -> 0]];

Cree una función para convertir de unidades de calendario de cuenta larga maya a una fecha juliana.

In[2]:=

JulianFromMayanLongCount[{baktun_, katun_, tun_, uinal_, kin_}] := epoch + 144000*baktun + 7200*katun + 360*tun + 20*uinal + kin

FromJulianDate puede ser usada para probar un ejemplo de entrada.

In[3]:=

example = JulianFromMayanLongCount[{7, 17, 18, 19, 2}]

Out[3]=

In[4]:=

FromJulianDate["Modified", example, TimeZone -> 0]

Out[4]=

Cree una función para convertir directamente de objetos de fecha maya de cuenta larga a gregorianos.

In[5]:=

GregorianFromMayanLongCount[date_] := DateValue[ FromJulianDate["Modified", JulianFromMayanLongCount[date], TimeZone -> 0], "Day", DateObject]

In[6]:=

GregorianFromMayanLongCount[{7, 17, 18, 19, 2}]

Out[6]=

Cree una función para convertir de una fecha juliana a unidades de calendario de cuenta larga maya.

In[7]:=

JulianToMayanLongCount[date_] := NumberDecompose[ Floor[date - epoch], {144000, 7200, 360, 20, 1} ]

JulianDate puede utilizarse para interpretar cualquier entrada de fecha en una fecha juliana, la cual es luego alimentada en una JulianToMayanLongCount.

In[8]:=

DateToMayanLongCount[date_] := Block[{$TimeZone = 0}, JulianToMayanLongCount[JulianDate["Modified", date]] ]

Esta función ahora aceptará cualquier entrada de fecha y regresará la correspondiente lista de fechas del calendario de cuenta larga maya.

In[9]:=

DateToMayanLongCount["May 4th, 2015"]

Out[9]=

In[10]:=

DateToMayanLongCount[AbsoluteTime[]]

Out[10]=

In[11]:=

DateToMayanLongCount[Today]

Out[11]=

Estas dos funciones pueden ser utilizadas para convertir de y a el calendario de cuenta larga maya.

In[12]:=

DateToMayanLongCount[{1900, 1, 1}]

Out[12]=

In[13]:=

DateToMayanLongCount[{1900, 1, 1}]; GregorianFromMayanLongCount[%]

Out[13]=