混合量

混合量会在以下多个情境中出现：货币、时间、距离、重量、角度等.

In[1]:=

Quantity[MixedMagnitude[{2, 35, 21.2}], MixedUnit[{"Hours", "Minutes", "Seconds"}]]

Out[1]=

In[2]:=

UnitConvert[Quantity[75.562, "AngularDegrees"], MixedUnit[{"AngularDegrees", "ArcMinutes", "ArcSeconds"}]]

Out[2]=

In[3]:=

Quantity[MixedMagnitude[{5, 11}], MixedUnit[{"Feet", "Inches"}]]

Out[3]=

In[4]:=

Quantity[MixedMagnitude[{5, 11}], MixedUnit[{"Feet", "Inches"}]]; % + Quantity[2.5, "Feet"]

Out[4]=

函数 SiderealTime 返回混合量. 找出你现在所在位置的当前恒星时（sidereal time）.

In[5]:=

stime = SiderealTime[]

Out[5]=

获取太阳当前位置的赤道坐标.

In[6]:=

sunpos = SunPosition[CelestialSystem -> "Equatorial"]

Out[6]=

计算月亮在统一坐标系统中的位置.

In[7]:=

moonpos = MoonPosition[CelestialSystem -> "Equatorial"]

Out[7]=

找出行星的赤经坐标.

In[8]:=

planetpos = QuantityMagnitude[ DeleteMissing[ EntityValue[EntityClass["Planet", All], EntityProperty["Planet", "RightAscension"]]], "HoursOfRightAscension"]

Out[8]=

将不同的位置度量结合进每一个天体的赤经列表中.

In[9]:=

ascensions = Join[ {0, moonpos[[1, 1]] - sunpos[[1, 1]]}, planetpos];

In[10]:=

gp = Sequence[GeoRange -> "World", GeoProjection -> {"AzimuthalEquidistant", "Centering" -> {-90, 0}}]; globe = GeoGraphics[{Thick, Black, Arrow[{{0, 0}, $GeoLocation}]}, gp, GeoBackground -> GeoStyling["ReliefMap"]][[1, 1]]; cross = {Thickness[.005], Opacity[.5], Line[9.5 {-#, #}]} & /@ {{0, 1}, {1, 0}}; shade = GeoGraphics[{Opacity[.5], GeoDisk[{-sunpos[[2, 1]], 180}, 10018758]}, gp, GeoBackground -> None][[1, 1]];

创建从南极观测时行星、太阳和月亮的位置图形视图.

In[11]:=

Rasterize[ Graphics[{globe, cross, shade, MapThread[ Text[Style[#3, #2, 24, FontWeight -> Bold], {0, 3.5}.RotationMatrix[(#1) \[Pi]/12]] &, {ascensions, {Yellow, White, Orange, Lighter[Blue], Red, Lighter[Purple], Orange, Cyan, Lighter[Blue]}, {"☼", "\[Moon]", "\[Mercury]", "\[Venus]", "\[Mars]", "\[Jupiter]", "\[Saturn]", "♅", "\[Neptune]"}}]}, Background -> GrayLevel[0.2], PlotRange -> 4, PlotLabel -> #, LabelStyle -> {Bold, White}, Axes -> None] &@stime, RasterSize -> 600, ImageSize -> 450]

Out[11]=