Medidas 

Calcule la longitud de arco de una malla en 1D, el área de una malla en 2D o el volumen de una malla en 3D.

In[1]:=

X mesh1d = DiscretizeRegion[Circle[]]; mesh2d = DiscretizeRegion[Disk[]]; mesh3d = DiscretizeRegion[Cuboid[], MaxCellMeasure -> \[Infinity]];

In[2]:=

X Grid[{{mesh1d, mesh2d, mesh3d}, {ArcLength[mesh1d], Area[mesh2d], Volume[mesh3d]}}]

Out[2]=

Calcule el centroide de cualquier malla.

In[3]:=

X Grid[{{Show[mesh1d, Graphics[{Red, Point[RegionCentroid[mesh1d]]}]], Show[mesh2d, Graphics[{Red, Point[RegionCentroid[mesh2d]]}]], Show[HighlightMesh[mesh3d, Style[2, Opacity[0.3]]], Graphics3D[{Red, PointSize[Large], Point[RegionCentroid[mesh3d]]}]]}}]

Out[3]=

Calcule el volumen de los diferentes niveles de una malla de procedimiento generado.

muestre la entrada completa de Wolfram Languageoculte la entrada

In[4]:=

X ArrayPatternMesh[a_?ArrayQ] := Module[{mp, pos, fpos, dims = Dimensions[a], cdims}, mp = RegionProduct @@ Map[MeshRegion[Partition[N[Range[0, #]]/#, 1], Line[Range[1, # + 1]]] &, dims]; pos = ArrayRules[a][[1 ;; -2, 1]]; cdims = Reverse[FoldList[Times, 1, dims[[2 ;; -1]]]]; fpos = 1 + (pos - 1).cdims; MeshRegion[MeshCoordinates[mp], MeshCells[mp, {Length[dims], fpos}]]]; drill[s_, t_] := Block[{sp, d = ArrayDepth[t], r = Length[s]/Length[t]}, If[r == 1, Mod[t s, 2], sp = Partition[s, Dimensions[s]/Dimensions[t]]; Flatten[MapThread[If[#1 == 0, #2 0, drill[#2, t]] &, {t, sp}, d], Transpose[Partition[Range[2 d], d]]]]]; SierpinskiArray[t_, k_] := Module[{s, dims = Dimensions[t]}, s = ConstantArray[1, dims^k]; drill[s, t]];

In[5]:=

X t = {{{1, 0}, {1, 1}}, {{0, 0}, {1, 0}}}; meshes = ArrayPatternMesh[SierpinskiArray[t, #]] & /@ Range[6]; Grid[{Part[meshes, 1 ;; 3], Part[meshes, 4 ;; 6]}]

Out[5]=

In[6]:=

X vols = Volume[#] & /@ meshes

Out[6]=

Encuentre una función que describa la secuencia de volúmenes.

In[7]:=

X FindSequenceFunction[Rationalize[vols], k]

Out[7]=