Relógio de contagem regressiva multiusuário
Defina um canal que mostre um relógio de contagem regressiva e uma função que impulsione a contagem regressiva.
In[1]:=
CreateChannel["Countdown",
HandlerFunctions ->
Association["MessageReceived" -> ((Countdown`$time = #Message) &)],
Initialization :>
CreateWindow[
DocumentNotebook[{Dynamic[
ClockGauge[$time, PlotTheme -> "Business"]]}],
WindowSize -> All, WindowElements -> {}, ShowCellBracket -> False,
Background -> Black, WindowFrameElements -> {"CloseBox"},
Selectable -> False, WindowTitle -> "Countdown",
CellContext -> "Countdown`"],
Permissions ->
Association["All" -> "Read", "Owner" -> {"Write", "Execute"}]]Out[1]=
In[2]:=
countdown[t_] :=
DynamicModule[{paused = True, lbl = "Pause", ii = t, up = None},
Row[{Button[Dynamic[If[paused, "Start", lbl]], paused = ! paused;
up = If[paused, None, UpdateInterval -> 1]],
Dynamic[Refresh[
If[ii >= 0 && ! paused,
" \[LongRightArrow] " <>
TextString[ChannelSend["Countdown", ii--]],
If[ii <= 0, up = None; lbl = "Done"]; ""], up,
TrackedSymbols :> {paused}]]}]]Inscreva-se no canal.
In[3]:=
listener = ChannelListen["Countdown"]Out[3]=
Configure uma contagem regressiva para um certo número de segundos e clique no botão para começar.
In[4]:=
countdown[20]Out[4]=
O relógio se atualiza enquanto a contagem regressiva ocorre, a não ser que você pause.
Out[5]=
Outros usuários podem se inscrever para o seu relógio de contagem regressiva referindo-se ao seu canal no ChannelListen.
In[6]:=
$WolframID <> ":Countdown"Out[6]=
In[7]:=
$WolframID <> ":Countdown";
ChannelListen[%]Out[7]=
