Создать веб-приложение с информацией о местах обитания животных: Новое в системе Wolfram Language 11

Создать веб-приложение с информацией о местах обитания животных

Интерфейс прикладного программирования RESTful использует тот же URL, но реагирует по-разному, в зависимости от применяемого метода протоколa передачи гипертекста (HTTP). GenerateHTTPResponse работает рекурсивно, поэтому функция Delayed, опираясь на APIFunction, обрабатывает различные методы протоколa передачи гипертекста для реализации веб-приложения с информацией о местах обитания животных.

Cоздадим простое приложение, которое определяет, методом геолокации, где были замечены различные виды животных.

In[1]:=

animallocator = Delayed[
   With[{query = HTTPRequestData["Query"]},
    Switch[HTTPRequestData["Method"],
     "POST",
     APIFunction[{"what" -> "Animal", 
       "where" -> "Location" :> $GeoLocation},
      (PutAppend[{#where, #what}, "locations.m"];
        "Thank you for your submission.") &],
     "GET",
     APIFunction[{"zoom" -> Restricted["Integer", {1, 18}] -> 14},
      GeoGraphics[
        Map[GeoMarker[First[#], Tooltip[Last[#]["Image"], Last[#]], 
           "Scale" -> Offset[80]] &, 
         Quiet[Check[ReadList["locations.m"], {}]]], 
        GeoZoomLevel -> #zoom, ImageSize -> 700] &, "PNG"],
     _, HTTPErrorResponse[400]
     ]
    ]];

Отчет о местах обитания животных будет выглядеть следующим образом:

In[2]:=

GenerateHTTPResponse[
  animallocator, <|"Method" -> "POST", 
   "Query" -> {"what" -> "coyote", "where" -> "40.083449,-88.200732"}|>];
GenerateHTTPResponse[
  animallocator, <|"Method" -> "POST", 
   "Query" -> {"what" -> "buffalo", 
     "where" -> "40.140722, -88.195257"}|>];
GenerateHTTPResponse[
  animallocator, <|"Method" -> "POST", 
   "Query" -> {"what" -> "beaver", "where" -> "40.063029,-87.9870"}|>];
GenerateHTTPResponse[
  animallocator, <|"Method" -> "POST", 
   "Query" -> {"what" -> "reindeer", "where" -> "40.29778, -88.2023"}|>];
GenerateHTTPResponse[animallocator, <|"Method" -> "POST", 
  "Query" -> {"what" -> "gopher", "where" -> "40.116420,-88.243383"}|>]

Out[2]=