Wolfram Language™

Conectividade dos municípios dos EUA

Construa o gráfico de conectividade entre municípios vizinhos dos Estados Unidos.

Pegue a lista de todos os municípios dos estados contíguos dos Estados Unidos.

In[1]:=

Length[counties = Flatten[EntityClass["AdministrativeDivision", "ContinentalUSStates"]["Subdivisions"]]]

Out[1]=

Adicione o Distrito de Columbia, que não é uma subdivisão de nenhum dos 48 estados contíguos.

In[2]:=

AppendTo[counties, Entity["AdministrativeDivision", {"DistrictOfColumbia", "DistrictOfColumbia", "UnitedStates"}]];

Calcule a lista de municípios que fazem fronteira com cada município.

In[3]:=

bordering = EntityValue[counties, "BorderingCounties"];

Descarte alguns casos para os quais a informação de limite não está disponível.

In[4]:=

Length[missingpos = Position[bordering, _Missing]]

Out[4]=

In[5]:=

counties = Delete[counties, missingpos]; bordering = Delete[bordering, missingpos];

Construa as bordas do gráfico de conectividade dos municípios dos Estados Unidos.

In[6]:=

Length[edges = DeleteDuplicates[ Sort /@ Flatten[ MapThread[Thread[UndirectedEdge[##]] &, {counties, bordering}]]]]

Out[6]=

In[7]:=

Graph[counties, edges]

Out[7]=

Para construir uma incorporação mais familiar, faça download da posição central de todos os municípios.

In[8]:=

pos = GeoPosition[EntityValue[counties, "Position"]]

Out[8]=

Use a seguinte projeção cartográfica.

In[9]:=

proj = {"LambertAzimuthal", "Centering" -> Entity["City", {"Topeka", "Kansas", "UnitedStates"}]};

In[10]:=

projpos = First@GeoGridPosition[pos, proj];

Assim você tem a seguinte incorporação de gráfico.

In[11]:=

graph = Graph[counties, edges, VertexCoordinates -> projpos]

Out[11]=

Para ir de San Francisco para Manhattan, você precisa visitar pelo menos 67 municípios, incluindo o inicial e o final.

In[12]:=

Length[path = FindShortestPath[graph, Entity[ "AdministrativeDivision", {"SanFranciscoCounty", "California", "UnitedStates"}], Entity[ "AdministrativeDivision", {"NewYorkCounty", "NewYork", "UnitedStates"}]]]

Out[12]=

In[13]:=

HighlightGraph[graph, PathGraph[path]]

Out[13]=