模拟随时间推移宇宙的组成: Wolfram语言 11 的新功能

‹›

模拟随时间推移宇宙的组成

探索宇宙组成随时间推移的变化，根据标准 ΛCDM （Λ-冷暗物质）模型.

计算暗能量、物质和辐射在宇宙的不同年龄段密度比值，范围在 1000 年到年之间。

In[1]:=

ages = Quantity[10^Range[3, 11, 0.2], "Years"];

In[2]:=

darkenergy = 
  Table[UniverseModelData[t, "DarkEnergyDensityRatio"], {t, ages}];
matter = Table[
   UniverseModelData[t, "MatterEnergyDensityRatio"], {t, ages}];
radiation = 
  Table[UniverseModelData[t, "RadiationEnergyDensityRatio"], {t, 
    ages}];

表示这三个组分随时间的演变，宇宙的当前年龄用竖线表示. 目前最大的组分是暗能量.

显示完整的 Wolfram 语言输入

In[3]:=

data = {
   Transpose[{ages, darkenergy}],
   Transpose[{ages, darkenergy + matter}],
   Transpose[{ages, darkenergy + matter + radiation}]
   };
ListLogLinearPlot[data,
 PlotRange -> All,
 Joined -> True,
 Filling -> {1 -> Axis, 2 -> {1}, 3 -> {2}},
 FrameLabel -> Automatic,
 GridLines -> {{13.8*10^9}, None},
 PlotRangePadding -> 0,
 Frame -> True, 
 PlotLegends -> {"DarkEnergyDensity", "MatterEnergyDensity", 
   "RadiationEnergyDensity"}]

Out[3]=

发现何时背景辐射温度在 273 和 373K 之间（宇宙的"宜居时代"）.

In[4]:=

period = t /. 
    FindRoot[
     Quantity[#, "Kelvins"] == 
      UniverseModelData[t, "RadiationTemperature"], {t, 
      Quantity[1, "Megayears"]}, Evaluated -> False] & /@ {273, 373}

Out[4]=

In[5]:=

Grid[{#, UniverseModelData[#, "RadiationTemperature"]} & /@ 
  Through[{Min, Mean, Max}[period]], Dividers -> All]

Out[5]=

Wolfram 语言™

模拟随时间推移宇宙的组成

相关范例