Изучение параметризации многообразия

Изучите параметризацию многообразия, к которой относятся входные данные, используя автокодировщик, сеть с узким слоем, изучающим реконструкцию первичного ввода.

Пример данных режима обучения из части синтезированного двумерного многообразия.

In[1]:=

manifold = Table[AngleVector[{x, 0.9 Pi x}] + x/20*RandomVariate[NormalDistribution[], 2], {x, 0, 1, 0.001}]; plot = ListPlot[manifold, PlotStyle -> Orange]

Out[1]=

Создайте сеть с узким слоем для изучения параметризации многообразия.

In[2]:=

net = NetChain[{25, Ramp, 1, 25, Ramp, 2}, "Input" -> 2]

Out[2]=

Создайте сеть потерь, которая рассчитывает потери, основанные на "ошибке восстановления" - измерение степени, до которой сеть может производить выход идентичный вводу.

In[3]:=

lossNet = NetGraph[{net, MeanSquaredLossLayer[]}, {1 -> 2, NetPort["Input"] -> NetPort[2, "Target"]}]

Out[3]=

Обучите сеть потерь на многообразии и выявите начальную сеть из сети потерь.

In[4]:=

lossNet = NetTrain[lossNet, <|"Input" -> manifold|>, BatchSize -> 4096]; trained = NetExtract[lossNet, 1];

Визуализируйте, как сеть проектирует произвольные точки на многообразие.

In[5]:=

{{xmin, xmax}, {ymin, ymax}} = CoordinateBounds[manifold, .2]; Show[plot, StreamPlot[ trained[{x, y}] - {x, y}, {x, xmin, xmax}, {y, ymin, ymax}]]

Out[5]=

Разделите сеть на сеть кодировщика и декодера (кодировщик параметризует точки, используя одиночную скалярную величину, в то время как декодер восстанавливает точку из параметризации).

In[6]:=

decoder = Drop[trained, 3] encoder = Take[trained, 3]

Out[6]=

Out[6]=

Раскрасьте каждую точку в оригинальном многообразии согласно её параметризации в кодировщике.

In[7]:=

ListPlot[Style[#, Hue[First[0.3 + encoder[#]]/3]] & /@ manifold]

Out[7]=

Получите диапазон параметризации путём применения кодировщика к многообразию.

In[8]:=

{min, max} = MinMax[encoder[manifold]]

Out[8]=

Изобразите восстановление в этом диапазоне наряду с оригинальным многообразием.

In[9]:=

Show[plot, ListLinePlot[Table[decoder[x], {x, min, max, .01}]]]

Out[9]=