Создание информационной коллекции EntityStore о болидах

Wolfram Knowledgebase содержит информацию, охватывающую множество различных областей в сочетании с функциональными возможностями для представления, доступа и вычислительных операций с этой информацией. Теперь пользователи могут создавать свои собственные коллекции информации и работать с ними, как если бы они изначально были частью базы знаний Wolfram. В данном примере показан процесс создания и использования коллекции информации о болидах на основе существующего информационного источника.

Воспользуемся функцией Import и загрузим данные о болидах, предоставленные Лабораторией реактивного движения.

In[1]:=

(rawdata = Import["http://neo.jpl.nasa.gov/fireballs/", "FullData"])[[3, 9, 2, 12, 1, ;; 5]]

Out[1]=

Определим функцию для преобразования необработанных данных на единицы для хранения в Wolfram Knowledgebase.

In[2]:=

AddUnits[x_, u_: "Kilometers"/"Seconds"] := If[NumberQ[x], Quantity[Interpreter["Number"][x], u], Missing["NotAvailable"]]

Извлечем необходимые компоненты загруженных данных, добавим соответствующие теги с помощью функции Quantity, а также создадим коллекцию сущностей на основе загруженных данных.

In[3]:=

bolidedata = DeleteCases[{ DateObject[#1], With[{i = Interpreter["GeoCoordinates"][#2 <> " " <> #3]}, If[Head[i] === Missing, i, GeoPosition[Join[i[[1]], If[NumberQ[#4], {#4 10^3}, {}]]]]], AddUnits[#5], AddUnits[#6], AddUnits[#7], AddUnits[#8], AddUnits[#9, "Joules"], AddUnits[#10, "MetricKilotons"] } & @@@ rawdata[[3, 9, 2, 12, 1, 2 ;;]], {_, _Missing, __}];

In[4]:=

entities = Association @@ MapIndexed[ "Bolide" <> ToString[First[#2]] -> <| "Date" -> #[[1]], "Position" -> #[[2]], "Velocity" -> #[[3]], "VelocityX" -> #[[4]], "VelocityY" -> #[[5]], "VelocityZ" -> #[[6]], "TotalRadiatedEnergy" -> #[[7]], "CalculatedTotalImpactEnergy" -> #[[8]], "Label" -> "bolide on " <> DateString[#[[1]]] <> " GMT" |> &, bolidedata];

In[5]:=

properties = <| "Date" -> <|"Label" -> "date"|>, "Position" -> <|"Label" -> "position"|>, "Velocity" -> <|"Label" -> "velocity"|>, "VelocityX" -> <|"Label" -> "velocity x\[Hyphen]component"|>, "VelocityY" -> <|"Label" -> "velocity y\[Hyphen]component"|>, "VelocityZ" -> <|"Label" -> "velocity z\[Hyphen]component"|>, "TotalRadiatedEnergy" -> <|"Label" -> "total radiated energy"|>, "CalculatedTotalImpactEnergy" -> <|"Label" -> "calculated total impact energy"|> |>;

In[6]:=

store = EntityStore["Bolide" -> <| "Label" -> "bolide", "LabelPlural" -> "bolides", "Entities" -> entities, "Properties" -> properties |>]

Out[6]=

Зарегистрируем полученную информационную коллекцию для данной сессии.

In[7]:=

PrependTo[$EntityStores, store];

Соберем информацию о позициях и энергетической заряженности болид в сеть ассоциаций "EntityAssociation".

In[8]:=

ea = EntityValue["Bolide", {"Position", "TotalRadiatedEnergy"}, "EntityAssociation"];

Создадим географическую карту мест наблюдения болид на основе их высоты и позиций в небе.

In[9]:=

GeoGraphics[{GeoVisibleRegion[#] & @@@ Values[ea]}]

Out[9]=

Извлечем энергетическую заряженность болид (в джоулях) и образуем ряд числовых значений QuantityArray.

In[10]:=

energies = QuantityArray[Values[ea][[All, -1]]]

Out[10]=

Визуализируем энергию болид с помощью гистограммы.

In[11]:=

Histogram[energies, "Log", AxesLabel -> {"energy (J)", "count"}]

Out[11]=

Применим функцию масштабирования, чтобы отобразить яркость болид.

In[12]:=

scale[e_] := Quantity[1.*10^4 Sqrt[e/Max[energies]], "Kilometers"]

In[13]:=

GeoGraphics[{Red, GeoDisk[#1, scale[#2]] & @@@ Values[ea]}]

Out[13]=