Wolfram Language™

Le pouvoir des Pokémon

La base de connaissances de Wolfram contient des informations sur les icônes de la culture populaire ainsi que des connaissances scientifiques. Ici, diverses caractéristiques physiques (points d'attaque et de défense, poids, couleur) de la ménagerie Pokémon sont explorées, contrastées et visualisées à l'aide du cadre d'entités intégré.

Tracez les distributions des points d'attaque et de défense de tous les Pokémon.

In[1]:=

PairedHistogram[EntityValue["Pokemon", "Attack"], EntityValue["Pokemon", "Defense"], ChartLabels -> {"attack", "defense"}, ChartStyle -> {{LightOrange, LightBlue}, None}]

Out[1]=

Créez un Dataset de points d'attaque et de points de défense pour les Pokémon de la génération VI et comparez-les les uns aux autres.

In[2]:=

stat = EntityValue[Entity[ "Pokemon", { "Generation" -> Entity[ "PokemonGeneration", "GenerationVI"]}], {"Attack", "Defense"}, "Dataset"];

In[3]:=

ListPlot[stat, PlotStyle -> Directive[Opacity[0.5], Orange, PointSize[Medium]], AxesLabel -> Automatic, LabelingFunction -> None]

Out[3]=

Comparez et tracez les poids moyens des Pokémon sur différentes générations.

In[4]:=

wg = Normal[ GroupBy[Rule @@@ EntityValue["Pokemon", {"Generation", "Weight"}], First -> Last, Mean]]

Out[4]=

In[5]:=

BarChart3D[wg[[All, 2]], ChartLegends -> wg[[All, 1]], ChartStyle -> 24]

Out[5]=

Utilisez une classe d'entités définie implicitement pour trouver les trois Pokémon les plus lourds.

In[6]:=

EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]

Out[6]=

In[7]:=

EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]; EntityValue[%, "Generation"]

Out[7]=

Utilisez une classe d'entités implicitement définie pour trouver les Pokémon jaunes dont le poids est compris entre 50 et 100 kg.

In[8]:=

yellowMidweights = EntityList[ Entity["Pokemon", {"PokedexColor" -> "Yellow", "Weight" -> Between[{ Quantity[50, "Kilograms"], Quantity[100, "Kilograms"]}]}]]

Out[8]=

Créez un collage de ces personnages de Pokémon avec des tailles basées sur leur poids.

In[9]:=

ImageCollage[ Rule @@@ EntityValue[yellowMidweights, {"Weight", "Image"}], Background -> White]

Out[9]=

Comparez les couleurs des Pokémon du groupe original (Génération I) et du groupe le plus récent (Génération VI).

In[10]:=

{color1, color6} = Sort[Tally[EntityValue[EntityList[ Entity["Pokemon", {"Generation" -> Entity["PokemonGeneration", #]}]], "PokedexColor"]]] & /@ {"GenerationI", "GenerationVI"};

In[11]:=

PieChart3D[{color1[[All, 2]], color6[[All, 2]]}, PlotLabel -> "Gen. I (outer) vs. Gen. VI (inner)", ChartElementFunction -> "ProfileSector3D", SectorOrigin -> {Automatic, 1}, ChartStyle -> (color1[[All, 1]] /. co_Entity :> Symbol[co[[2]]]), ChartLegends -> color1[[All, 1]]]

Out[11]=