Wolfram Language™

Le yoga pour la santé et la connaissance

La base de connaissances de Wolfram comprend un jeu de données sur les poses de yoga. Ainsi, les relations entre les postures, leurs niveaux de difficulté, les muscles qu'elles impliquent, leurs durées et bien d'autres caractéristiques peuvent être explorées et étudiées d'une manière simple, puissante, précise et entièrement programmatique.

Formez et visualisez les relations entre les postures de yoga sur la base des relations "PreparatoryPoses", en commençant par la pose du scorpion.

In[1]:=

poseGraph = NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &, Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name", VertexLabelStyle -> LightGray]

Out[1]=

Affichez des schémas de différentes poses.

In[2]:=

With[{v = Take[VertexList[poseGraph], 5]}, schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}] ] // Column

Out[2]=

Réalisez un tracé des poses regroupées par « communautés » qui partagent des liens entre elles.

In[3]:=

CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e, VertexLabels -> Placed["Name", Tooltip]]

Out[3]=

Comptez le nombre de muscles contractés dans la série de poses de la séquence de yoga primaire Ashtanga et faites un tracé par rapport au nombre de muscles engagés.

In[4]:=

mus = Normal[ EntityValue[ Cases[Entity["YogaSequence", "AshtangaPrimarySeries"][ "PrimaryPoseSequence"] /. Entity["YogaSequence", s_] :> Entity["YogaSequence", s]["PrimaryPoseSequence"], _Entity, Infinity], "PrimaryContractedMuscles", "EntityAssociation"]] /. Rule[l_, r_] :> l -> Length[r];

In[5]:=

ListLinePlot[mus[[All, -1]], Filling -> Axis, AspectRatio -> .4, AxesLabel -> {"pose position", "contracted muscles count"}]

Out[5]=

Trouvez les muscles qui sont étirés dans la série de poses de la salutation au soleil A et visualisez le muscle le plus souvent étiré.

In[6]:=

muscles = (SortBy[ Tally[DeleteMissing[ Flatten[EntityValue[ Cases[Entity["YogaSequence", "SunSalutationA"][ "PrimaryPoseSequence"], _Entity, Infinity], "StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &

Out[6]=

Visualisez le muscle le plus fréquemment étiré.

In[7]:=

EntityValue[muscles[[1, 1]], "RegionalLocationImage"]

Out[7]=

Utilisez une classe d'entités implicitement définie pour trouver et visualiser des postures de yoga d'intensité moyenne pour débutants qui étirent les jambes et renforcent le tronc.

In[8]:=

EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]

Out[8]=

Visualisez des schémas de ces poses sous la forme d'une association d'entités.

In[9]:=

EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]; EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]

Out[9]=

Affichez des postures de yoga avancées qui renforcent l'iliopsoas et étirent les ischio-jambiers.

In[10]:=

EntityValue[ Entity["YogaPose", {"ExperienceLevel" -> "Advanced", "PrimaryContractedMuscles" -> Entity["AnatomicalStructure", "Iliopsoas"], "StretchedMuscles" -> Entity["AnatomicalStructure", "SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]

Out[10]=

Trouvez des séquences de yoga d'une durée comprise entre 30 et 60 minutes.

In[11]:=

EntityList@ Entity["YogaSequence", {"EstimatedDuration" -> Quantity[ Interval[{30, 60}], "Minutes"]}]

Out[11]=