Wolfram 언어

풍부한 Knowledgebase 액세스

건강과 지식을 위한 요가

Wolfram Knowledgebase는 요가 자세에 대한 데이터를 요약한 정선된 데이터 집합이 포함되어 있어, 결과적으로 포즈와 각각의 난이도, 사용되는 근육, 지속 시간 등 다양한 특징을 간단하고 강력하며, 정확하고 완전히 프로그램 가능한 방법으로 탐구하고 배울수 있도록 설계 되었습니다.

전갈의 포즈를 시작으로 "PreparatoryPoses"의 관계에 근거한 요가 자세의 관계를 형성하고 시각화합니다.

In[1]:=
Click for copyable input
poseGraph = NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &, Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name", VertexLabelStyle -> LightGray]
Out[1]=

다양한 포즈의 간단한 이미지를 표시합니다.

In[2]:=
Click for copyable input
With[{v = Take[VertexList[poseGraph], 5]}, schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}] ] // Column
Out[2]=

연결 동작을 공유하는 "커뮤니티"에 의한 포즈를 그룹화하여 플롯합니다.

In[3]:=
Click for copyable input
CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e, VertexLabels -> Placed["Name", Tooltip]]
Out[3]=

아쉬탕가 요가 동작의 일련의 포즈 수행시 수축하는 근육을 세고 사용되는 근육 수와 함께 플롯합니다.

전체 Wolfram 언어 입력 표시하기
In[4]:=
Click for copyable input
mus = Normal[ EntityValue[ Cases[Entity["YogaSequence", "AshtangaPrimarySeries"][ "PrimaryPoseSequence"] /. Entity["YogaSequence", s_] :> Entity["YogaSequence", s]["PrimaryPoseSequence"], _Entity, Infinity], "PrimaryContractedMuscles", "EntityAssociation"]] /. Rule[l_, r_] :> l -> Length[r];
In[5]:=
Click for copyable input
ListLinePlot[mus[[All, -1]], Filling -> Axis, AspectRatio -> .4, AxesLabel -> {"pose position", "contracted muscles count"}]
Out[5]=

태양 예배 요가 동작의 일련의 포즈 수행시 이완되는 근육을 구하고 가장 빈번하게 이완되는 근육을 시각화합니다.

In[6]:=
Click for copyable input
muscles = (SortBy[ Tally[DeleteMissing[ Flatten[EntityValue[ Cases[Entity["YogaSequence", "SunSalutationA"][ "PrimaryPoseSequence"], _Entity, Infinity], "StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &
Out[6]=

가장 빈번히 이완되는 근육을 시각화합니다.

In[7]:=
Click for copyable input
EntityValue[muscles[[1, 1]], "RegionalLocationImage"]
Out[7]=

간접적으로 정의된 엔티티 클래스를 사용하여 다리를 늘리고 몸통 (코어)을 단련하는 초보자용 중간 강도의 요가 포즈을 찾아 시각화합니다.

In[8]:=
Click for copyable input
EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]
Out[8]=

이러한 포즈의 간단한 이미지를 엔티티의 연상으로 살펴봅니다.

In[9]:=
Click for copyable input
EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]; EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]
Out[9]=

장요근을 단련하고 무릎 힘줄을 스트레칭하는 상급자용 요가 포즈를 표시합니다.

In[10]:=
Click for copyable input
EntityValue[ Entity["YogaPose", {"ExperienceLevel" -> "Advanced", "PrimaryContractedMuscles" -> Entity["AnatomicalStructure", "Iliopsoas"], "StretchedMuscles" -> Entity["AnatomicalStructure", "SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]
Out[10]=

지속 시간이 30분에서 60분 사이의 일련의 요가 자세를 구합니다.

In[11]:=
Click for copyable input
EntityList@ Entity["YogaSequence", {"EstimatedDuration" -> Quantity[ Interval[{30, 60}], "Minutes"]}]
Out[11]=

관련 예제

de en es fr ja pt-br ru zh