Datos de fuentes de Internet: Nuevo en Wolfram Language 11

Datos de fuentes de Internet

Descargue diariamente las temperaturas promedio para el año anterior para los Grandes Lagos.

In[1]:=

rawdata = 
  Import["http://coastwatch.glerl.noaa.gov/ftp/glsea/avgtemps/glsea-\
temps_1024.dat", "Data"];

Las observaciones empiezan en la fila 11.

In[2]:=

rawdata[[;; 11]]

Out[2]=

El número de observaciones.

In[3]:=

Length[obs]

Out[3]=

Defina la lista de lagos.

In[4]:=

lakes = {"Superior", "Michigan", "Huron", "Erie", "Ontario", 
   "St. Clair"};

muestre la entrada completa de Wolfram Language

In[5]:=

en = {Entity["Lake", "LakeSuperior::52tvr"], 
   Entity["Lake", "LakeMichigan::y3357"], 
   Entity["Lake", "LakeHuron::5t8vh"], 
   Entity["Lake", "LakeErie::6tm6r"], 
   Entity["Lake", "LakeOntario::35gt7"], 
   Entity["Lake", "LakeSaintClair::3r368"]};
markers = 
  Map[Text[Style[
      StringReplace[StringTrim[#["Name"], "Lake"], "Saint" -> "St."], 
      Bold, 12, Black, FontFamily -> "Arial"], #["Position"], 
     Right] &, en];
GeoGraphics[{EntityClass["Lake", "GreatLakes"], markers}, 
 GeoCenter -> GeoPosition[{46, -84}], 
 GeoRange -> {{40, 50}, {-93, -74}}, 
 GeoBackground -> 
  GeoStyling["ReliefMap", 
   ColorFunction -> (ColorData["RedBlueTones"][1 - #] &)], 
 ImageSize -> Medium]

Out[5]=

Cree datos que sirvan de marcas de tiempo en una TimeSeries.

In[6]:=

dates = Table[
   DatePlus[{obs[[k, 1]], 1, 1}, Quantity[obs[[k, 2]], "Days"]], {k, 
    1, Length[obs]}];

Use QuantityArray para almacenar las temperaturas y la unidad.

In[7]:=

values = QuantityArray[obs[[All, 3 ;;]], "DegreesCelsius"]

Out[7]=

Almacene la lista de los lagos como MetaInformation que puede ser recuperada para ser utilizada más adelante, por ejemplo, para crear leyendas de gráfico.

In[8]:=

ts = TimeSeries[values, {dates}, 
  MetaInformation -> {"Lakes" -> lakes}]

Out[8]=

In[9]:=

DateListPlot[ts, PlotLegends -> ts["Lakes"], PlotTheme -> "Detailed", 
 FrameLabel -> Automatic]

Out[9]=

Estudie las estadísticas descriptivas para cada lago.

In[10]:=

stats = {Min, Max, Mean, Median, StandardDeviation};
summary[lake_] := Map[#[lake] &, stats]

In[11]:=

TableForm[
 Table[summary[ts["PathComponent", k]], {k, 1, Length[lakes]}], 
 TableHeadings -> {lakes, stats}]

Out[11]//TableForm=

Wolfram Language™

Datos de fuentes de Internet

Ejemplos relacionados