Misiones espaciales tripuladas

MannedSpaceMissionData proporciona información histórica y actualizada acerca de la exploración humana en el espacio.

In[1]:=

missions = MannedSpaceMissionData[];

Usted puede crear un EventSeries con base en la fecha de lanzamiento de las misiones con valores de vector narrando la misión como entidad y la duración de cada misión.

In[2]:=

data = DeleteMissing[ MannedSpaceMissionData[ missions, {"LaunchDate", "Entity", "MissionDuration"}], 1, 2];

In[3]:=

es = EventSeries[data[[All, {2, 3}]], {data[[All, 1]]}]

Out[3]=

El gráfico TimelinePlot de las marcas de tiempo muestra el intervalo casi continuo de las misiones espaciales tripuladas desde 1961.

In[4]:=

TimelinePlot[es["Dates"]]

Out[4]=

Para analizar las duraciones de las misiones, extraiga el segundo componente de la serie de eventos original y convierta los valores a horas.

In[5]:=

durations = UnitConvert[es["PathComponent", 2], "Hours"]

Out[5]=

Las misiones más cortas son más comunes.

In[6]:=

Histogram[durations, Quantity[{0, 6000, 500}, "Hours"], AxesLabel -> Automatic]

Out[6]=

In[7]:=

x1 = 250; x2 = 4500; line1 = {{es["FirstDate"], x1}, {es["LastDate"], x1}}; line2 = {{es["FirstDate"], x2}, {es["LastDate"], x2}}; opts = {Joined -> {False, True, True}, Filling -> {1 -> 0}, PlotLabels -> {None, Quantity[x1, "Hours"], UnitConvert[Quantity[N[x2, 4], "Hours"], "Days"]}};

In[8]:=

DateListPlot[{durations, line1, line2}, opts]

Out[8]=

Calcule algunas estadísticas descriptivas de las duraciones de las misiones. Note que la media y la mediana están alejadas una de otra, indicando una larga cola de distribución.

In[9]:=

stats = {Min, Max, Mean, Median}; convert := UnitConvert[N[#], MixedUnit[{"Months", "Days", "Hours", "Minutes"}]] &

In[10]:=

TableForm[Map[convert[#[durations]] &, stats], TableHeadings -> {stats}]

Out[10]//TableForm=

El tiempo total en que un humano ha estado en el espacio.

In[11]:=

UnitConvert[Total[durations], MixedUnit[{"Years", "Months", "Days", "Hours", "Minutes", "Seconds"}]]

Out[11]=