Wolfram Language™

Tableaux de quantités

QuantityArray permet le stockage et la manipulation efficace de tableaux d'objets de Quantity, et elle est donc idéale pour l'analyse des données avec des unités physiques. En continuant avec l'intégration des quantités dans tout le système, plusieurs fonctions comprennent maintenant ou le retour des objets QuantityArray.

Échantillonnez des objets QuantityDistribution.

In[1]:=

RandomVariate[ParetoDistribution[Quantity[500., "USDollars"], 4], 300]

Out[1]=

Un objet QuantityArray est équivalent à un tableau normal d'éléments de Quantity.

In[2]:=

RandomVariate[ParetoDistribution[Quantity[500., "USDollars"], 4], 300]; Normal[Take[%, 10]]

Out[2]=

Calculez ou téléchargez des tableaux de données géographiques, comme les données d'élévation ou champ magnétique.

In[3]:=

GeoElevationData[Entity["Country", "UnitedStates"]]

Out[3]=

In[4]:=

GeomagneticModelData[ Entity["GeographicRegion", "Antarctica"], "Magnitude"]

Out[4]=

Manipulez des tableaux d'angles latitude et de longitude.

In[5]:=

GeoElevationData[ Entity["Country", "UnitedStates"], "Undulation", GeoPosition]

Out[5]=

In[6]:=

GeoElevationData[ Entity["Country", "UnitedStates"], "Undulation", GeoPosition]; LatitudeLongitude[%]

Out[6]=

Obtenez un tableau de données pour la composante verticale du champ gravitationnel sur la Chine.

In[7]:=

data = GeogravityModelData[Entity["Country", "China"], "DownComponent"]

Out[7]=

Examinez comment le champ gravitationnel diffère de la valeur standard de 9.81 sur cette région.

In[8]:=

contourplot = ListContourPlot[data - Quantity[1, "StandardAccelerationOfGravity"], Frame -> False, PlotRangePadding -> 0, ColorFunction -> "SolarColors"]

Out[8]=

Superposez le tracé de contour sur une carte de la Chine.

In[9]:=

Legended[GeoGraphics[{GeoStyling[{"GeoImage", contourplot}, Opacity[0.8]], Polygon[Entity["Country", "China"]]}, ImageSize -> 500, GeoRange -> Quantity[2200, "Kilometers"], GeoZoomLevel -> 5], BarLegend[{"SolarColors", MinMax@Flatten[QuantityMagnitude@data]}]]

Out[9]=