Wolfram Language

Unités et dates

Convertissez le calendrier maya

Identifiez l'époque (ou la date de début) du calendrier maya à compte long en tant que date julienne.

In[1]:=
Click for copyable input
epoch = JulianDate["Modified", DateObject[{-3114, 8, 11}, TimeZone -> 0]];

Créez une fonction pour convertir les unités de calendrier à compte long à une date julienne.

In[2]:=
Click for copyable input
JulianFromMayanLongCount[{baktun_, katun_, tun_, uinal_, kin_}] := epoch + 144000*baktun + 7200*katun + 360*tun + 20*uinal + kin

FromJulianDate peut être utilisée pour tester un exemple d'entrée.

In[3]:=
Click for copyable input
example = JulianFromMayanLongCount[{7, 17, 18, 19, 2}]
Out[3]=
In[4]:=
Click for copyable input
FromJulianDate["Modified", example, TimeZone -> 0]
Out[4]=

Créer une fonction pour convertir directement le compte long maya en objets de date grégoriens.

In[5]:=
Click for copyable input
GregorianFromMayanLongCount[date_] := DateValue[ FromJulianDate["Modified", JulianFromMayanLongCount[date], TimeZone -> 0], "Day", DateObject]
In[6]:=
Click for copyable input
GregorianFromMayanLongCount[{7, 17, 18, 19, 2}]
Out[6]=

Créez une fonction pour convertir une date julienne en unités du calendrier maya à compte long.

In[7]:=
Click for copyable input
JulianToMayanLongCount[date_] := NumberDecompose[ Floor[date - epoch], {144000, 7200, 360, 20, 1} ]

JulianDate peut être utilisée pour interpréter toute entrée de date en une date julienne, qui est ensuite alimentée dans une JulianToMayanLongCount.

In[8]:=
Click for copyable input
DateToMayanLongCount[date_] := Block[{$TimeZone = 0}, JulianToMayanLongCount[JulianDate["Modified", date]] ]

Cette fonction acceptera désormais n'importe quelle date et renverra la liste des dates du calendrier maya du compte long.

In[9]:=
Click for copyable input
DateToMayanLongCount["May 4th, 2015"]
Out[9]=
In[10]:=
Click for copyable input
DateToMayanLongCount[AbsoluteTime[]]
Out[10]=
In[11]:=
Click for copyable input
DateToMayanLongCount[Today]
Out[11]=

Ces deux fonctions peuvent être utilisées pour convertir le calendrier maya à compte long.

In[12]:=
Click for copyable input
DateToMayanLongCount[{1900, 1, 1}]
Out[12]=
In[13]:=
Click for copyable input
DateToMayanLongCount[{1900, 1, 1}]; GregorianFromMayanLongCount[%]
Out[13]=

Exemples connexes

de en es ja ko pt-br ru zh