Encuentre el equilibrio químico de redes de reacciones 

Los sistemas de reacciones químicas que tienen equilibrio típicamente se pueden modelar directamente como un sistema de ecuaciones polinomio. Estos problemas se definen por las ecuaciones de conservación y de reacción. El siguiente ejemplo es de una combustión química y modela la quema de combustible en una cámara de combustión, tales como en un motor de automóvil. La meta es determinar cuáles componentes y compuestos químicos están en la cámara de combustión en varias etapas. El sistema de reacciones que está siendo estudiado es dado por , , , , , , .

Introduzca una variable para la cantidad de cada componente. Aquí es tratado como un componente, dado que no ocurre por sí mismo.

También introduzca una variable para la cantidad de cada compuesto.

In[1]:=

X vars = {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[ x, 4], Subscript[x, 5], Subscript[x, 6], Subscript[x, 7], Subscript[x, 8], Subscript[x, 9], Subscript[x, 10]};

Si usted asume un sistema químico cerrado, las cantidades se conservan, lo que conduce a las ecuaciones de conservación mostradas en su notación química y algebraica.

In[2]:=

X conservation = {Subscript[x, 2] + 2 Subscript[x, 6] + Subscript[x, 9] + 2 Subscript[x, 10] == Subscript[T, H], Subscript[x, 3] + Subscript[x, 8] == Subscript[T, CO], Subscript[x, 1] + Subscript[x, 3] + 2 Subscript[x, 5] + 2 Subscript[x, 8] + Subscript[x, 9] + Subscript[x, 10] == Subscript[T, O], Subscript[x, 4] + 2 Subscript[x, 7] == Subscript[T, N]};

Proporcione las ecuaciones de equilibrio.

In[3]:=

X equilibrium = {Subscript[x, 5] == Subscript[R, 1] Subscript[x, 1]^2, Subscript[x, 6] == Subscript[R, 2] Subscript[x, 2]^2, Subscript[x, 7] == Subscript[R, 3] Subscript[x, 4]^2, Subscript[x, 8] == Subscript[R, 4] Subscript[x, 1] Subscript[x, 3], Subscript[x, 9] == Subscript[R, 5] Subscript[x, 1] Subscript[x, 2], Subscript[x, 10] == Subscript[R, 6] Subscript[x, 1] Subscript[x, 2]^2};

Proporcione valores de parámetros.

In[4]:=

X pars = {Subscript[T, O] -> 5 10^-5, Subscript[T, CO] -> 3 10^-5, Subscript[T, H] -> 1 10^-5, Subscript[T, N] -> 1 10^-5, Subscript[R, 1] -> 24.528, Subscript[R, 2] -> 22.206, Subscript[R, 3] -> 47.970, Subscript[R, 4] -> 24.942, Subscript[R, 5] -> 22.120, Subscript[R, 6] -> 46.989};

Resuelva el sistema en los reales y seleccione sólo las soluciones no negativas.

In[5]:=

X rsols = NSolve[Join[conservation, equilibrium] /. pars, vars, Reals];

In[6]:=

X Thread[vars -> SelectFirst[vars /. rsols, VectorQ[#, NonNegative] &]]

Out[6]=

Calcule una solución de mayor precisión.

In[7]:=

X rsols = NSolve[ SetPrecision[Join[conservation, equilibrium] /. pars, 20], vars, Reals, WorkingPrecision -> 20];

In[8]:=

X Thread[vars -> SelectFirst[vars /. rsols, VectorQ[#, NonNegative] &]]

Out[8]=