Explore la curvatura de la Tierra 

Muestre cómo la curvatura de la Tierra afecta rutas en su superficie.

Defina una ruta que empiece en la Torre Eiffel y viaje 100 km a lo largo de líneas geodésicas en cada una de las cuatro direcciones de la brújula en turno.

In[1]:=

X start = Entity["Building", "TourEiffel"][ EntityProperty["Building", "Position"]]; d = Quantity[100, "Kilometers"]; path = {GeoDisplacement[{d, "North"}, "Geodesic"], GeoDisplacement[{d, "East"}, "Geodesic"], GeoDisplacement[{d, "South"}, "Geodesic"], GeoDisplacement[{d, "West"}, "Geodesic"]};

Trace los cuatro segmentos de la ruta y amplifique para verificar que no se cierran debido a la curvatura de la Tierra.

In[2]:=

X GraphicsRow[ Apply[GeoGraphics[{Red, PointSize[Large], Point[start], Darker[Green], Thickness[Large], GeoPath[{start, path}]}, ##1] &, {{}, {GeoCenter -> start, GeoRange -> Quantity[3, "Kilometers"]}}, {1}]]

Out[2]=

Encuentre la distancia entre los puntos de inicio y final.

In[3]:=

X GeoDistance[start, Last[GeoDestination[start, path]]]

Out[3]=

Ahora siga los segmentos loxodrómicos (curvas de rumbo constante) en lugar de las geodésicas.

In[4]:=

X d = Quantity[100, "Kilometers"]; path = {GeoDisplacement[{d, "North"}, "Rhumb"], GeoDisplacement[{d, "East"}, "Rhumb"], GeoDisplacement[{d, "South"}, "Rhumb"], GeoDisplacement[{d, "West"}, "Rhumb"]};

La latitud del punto final coincide con la del principio, pero no su longitud.

In[5]:=

X GraphicsRow[ Apply[GeoGraphics[{Red, PointSize[Large], Point[start], Darker[Green], Thickness[Large], GeoPath[{start, path}]}, ##1] &, {{}, {GeoCenter -> start, GeoRange -> Quantity[3, "Kilometers"]}}, {1}]]

Out[5]=

Encuentre la distancia entre los puntos de inicio y final.

In[6]:=

X GeoDistance[start, Last[GeoDestination[start, path]]]

Out[6]=