Arbeiten mit unregelmäßigen Zeitreihen  

Entnehmen Sie zu zufälligen Ankunftszeiten Stichproben in Poisson-Prozessen.

In[1]:=

X poi = PoissonProcess[1.2]; data = TimeSeries[RandomFunction[poi, {0, 100}]]

Out[1]=

In[2]:=

X RegularlySampledQ[data]

Out[2]=

Visualisieren Sie die Zeitreihe.

In[3]:=

X ListPlot[data, Filling -> Axis, ImageSize -> 300]

Out[3]=

Subtrahieren Sie mit TimeSeriesMapThread die Mittelwertfunktion von der Zeitreihe.

In[4]:=

X mf[t_] = Mean[poi[t]]; cdata = TimeSeriesMapThread[Function[{t, x}, x - mf[t]], data];

In[5]:=

X ListPlot[cdata, Filling -> Axis, ImageSize -> 300]

Out[5]=

Berechnen Sie mit MovingMap den Mittelwert über einem zentrierten Sliding Window konstanter Breite.

In[6]:=

X mts = MovingMap[Mean, cdata, {{{10}}, Center}, "Reflected"];

Die gesamte Wolfram-Language Eingabe zeigenEingabe verbergen

In[7]:=

X ListPlot[{mts, cdata}, Filling -> {1 -> Axis}, Joined -> {False, True}, ImageSize -> 300]

Out[7]=

Erstellen Sie mit TimeSeriesAggregate regelmäßige Zeitreihen der größten Werte in nicht überlappenden Fenstern konstanter Breite.

In[8]:=

X adata = TimeSeriesAggregate[data, {10, Right}, Max];

Die gesamte Wolfram-Language Eingabe zeigenEingabe verbergen

In[9]:=

X ListPlot[{data, TimeSeriesWindow[adata, {0, 100}]}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "max-aggregated time series"}]

Out[9]=

In[10]:=

X RegularlySampledQ[adata]

Out[10]=

Nehmen Sie erneut Stichproben in Zehnerschritten mit Interpolation der Ordnung 0.

In[11]:=

X rdata = TimeSeriesResample[data, 10, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}];

Die gesamte Wolfram-Language Eingabe zeigenEingabe verbergen

In[12]:=

X ListPlot[{data, rdata}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "resampled time series"}]

Out[12]=

In[13]:=

X RegularlySampledQ[rdata]

Out[13]=

Verwenden Sie die ursprüngliche Zeitreihe als regelmäßige Zeitreihe in Funktionen, die solch eine einheitliche Dateneingabe verlangen.

In[14]:=

X regdata = TimeSeries[data, TemporalRegularity -> True]

Out[14]=

In[15]:=

X data["Path"] == regdata["Path"]

Out[15]=

In[16]:=

X RegularlySampledQ[regdata]

Out[16]=