不規則な時系列を操作する 

ランダムな到着時間で抽出されたポワソン過程のサンプルを取り出す．

In[1]:=

X poi = PoissonProcess[1.2]; data = TimeSeries[RandomFunction[poi, {0, 100}]]

Out[1]=

In[2]:=

X RegularlySampledQ[data]

Out[2]=

時系列を可視化する．

In[3]:=

X ListPlot[data, Filling -> Axis, ImageSize -> 300]

Out[3]=

TimeSeriesMapThreadを使って，時系列から平均値関数を引く．

In[4]:=

X mf[t_] = Mean[poi[t]]; cdata = TimeSeriesMapThread[Function[{t, x}, x - mf[t]], data];

In[5]:=

X ListPlot[cdata, Filling -> Axis, ImageSize -> 300]

Out[5]=

MovingMapを使って，中央揃えの一定幅の移動窓上で平均を計算する．

In[6]:=

X mts = MovingMap[Mean, cdata, {{{10}}, Center}, "Reflected"];

完全なWolfram言語入力を表示する入力を隠す

In[7]:=

X ListPlot[{mts, cdata}, Filling -> {1 -> Axis}, Joined -> {False, True}, ImageSize -> 300]

Out[7]=

TimeSeriesAggregateを使って，一定幅の重ならない窓で最大値の一定間隔時系列を構築する．

In[8]:=

X adata = TimeSeriesAggregate[data, {10, Right}, Max];

完全なWolfram言語入力を表示する入力を隠す

In[9]:=

X ListPlot[{data, TimeSeriesWindow[adata, {0, 100}]}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "max-aggregated time series"}]

Out[9]=

In[10]:=

X RegularlySampledQ[adata]

Out[10]=

次数0の補間を使って，10のステップでリサンプリングする．

In[11]:=

X rdata = TimeSeriesResample[data, 10, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}];

完全なWolfram言語入力を表示する入力を隠す

In[12]:=

X ListPlot[{data, rdata}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "resampled time series"}]

Out[12]=

In[13]:=

X RegularlySampledQ[rdata]

Out[13]=

一様に抽出された入力を要求する関数で使用するために，もとの時系列を規則的に抽出されたものとして扱う．

In[14]:=

X regdata = TimeSeries[data, TemporalRegularity -> True]

Out[14]=

In[15]:=

X data["Path"] == regdata["Path"]

Out[15]=

In[16]:=

X RegularlySampledQ[regdata]

Out[16]=