Trabaje con series temporales irregulares 

Obtenga una muestra de proceso de Poisson, muestreada en momentos aleatorios de llegadas.

In[1]:=

X poi = PoissonProcess[1.2]; data = TimeSeries[RandomFunction[poi, {0, 100}]]

Out[1]=

In[2]:=

X RegularlySampledQ[data]

Out[2]=

Visualice las series temporales.

In[3]:=

X ListPlot[data, Filling -> Axis, ImageSize -> 300]

Out[3]=

Use TimeSeriesMapThread para restar la función media de la serie temporal.

In[4]:=

X mf[t_] = Mean[poi[t]]; cdata = TimeSeriesMapThread[Function[{t, x}, x - mf[t]], data];

In[5]:=

X ListPlot[cdata, Filling -> Axis, ImageSize -> 300]

Out[5]=

Use MovingMap para calcular la media sobre una ventana deslizante centrada de anchura constante.

In[6]:=

X mts = MovingMap[Mean, cdata, {{{10}}, Center}, "Reflected"];

muestre la entrada completa de Wolfram Languageoculte la entrada

In[7]:=

X ListPlot[{mts, cdata}, Filling -> {1 -> Axis}, Joined -> {False, True}, ImageSize -> 300]

Out[7]=

Use TimeSeriesAggregate para construir series temporales regularmente espaciadas de los valores más grandes en ventanas de anchura constante no superpuestas.

In[8]:=

X adata = TimeSeriesAggregate[data, {10, Right}, Max];

muestre la entrada completa de Wolfram Languageoculte la entrada

In[9]:=

X ListPlot[{data, TimeSeriesWindow[adata, {0, 100}]}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "max-aggregated time series"}]

Out[9]=

In[10]:=

X RegularlySampledQ[adata]

Out[10]=

Vuelva a muestrear con un paso de 10 usando la interpolación de orden 0.

In[11]:=

X rdata = TimeSeriesResample[data, 10, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}];

muestre la entrada completa de Wolfram Languageoculte la entrada

In[12]:=

X ListPlot[{data, rdata}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "resampled time series"}]

Out[12]=

In[13]:=

X RegularlySampledQ[rdata]

Out[13]=

Trate la serie temporal original como muestreada regularmente para el uso en funciones que requieren tal entrada muestreada de forma uniforme.

In[14]:=

X regdata = TimeSeries[data, TemporalRegularity -> True]

Out[14]=

In[15]:=

X data["Path"] == regdata["Path"]

Out[15]=

In[16]:=

X RegularlySampledQ[regdata]

Out[16]=