运用不规则时间序列 

提取在随机抵达时间采样的泊松过程样本.

In[1]:=

X poi = PoissonProcess[1.2]; data = TimeSeries[RandomFunction[poi, {0, 100}]]

Out[1]=

In[2]:=

X RegularlySampledQ[data]

Out[2]=

可视化时间序列.

In[3]:=

X ListPlot[data, Filling -> Axis, ImageSize -> 300]

Out[3]=

用 TimeSeriesMapThread 从时间序列中减去均值函数.

In[4]:=

X mf[t_] = Mean[poi[t]]; cdata = TimeSeriesMapThread[Function[{t, x}, x - mf[t]], data];

In[5]:=

X ListPlot[cdata, Filling -> Axis, ImageSize -> 300]

Out[5]=

用 MovingMap 在置中的固定宽度滑动窗口计算均值.

In[6]:=

X mts = MovingMap[Mean, cdata, {{{10}}, Center}, "Reflected"];

显示完整的 Wolfram 语言输入隐藏输入

In[7]:=

X ListPlot[{mts, cdata}, Filling -> {1 -> Axis}, Joined -> {False, True}, ImageSize -> 300]

Out[7]=

用 TimeSeriesAggregate 为固定宽度的非重叠性窗口中的最大数值构建固定间隔的时间序列.

In[8]:=

X adata = TimeSeriesAggregate[data, {10, Right}, Max];

显示完整的 Wolfram 语言输入隐藏输入

In[9]:=

X ListPlot[{data, TimeSeriesWindow[adata, {0, 100}]}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "max-aggregated time series"}]

Out[9]=

In[10]:=

X RegularlySampledQ[adata]

Out[10]=

用0阶插值对步长为10进行重新采样.

In[11]:=

X rdata = TimeSeriesResample[data, 10, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}];

显示完整的 Wolfram 语言输入隐藏输入

In[12]:=

X ListPlot[{data, rdata}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "resampled time series"}]

Out[12]=

In[13]:=

X RegularlySampledQ[rdata]

Out[13]=

对于需要统一采样输入的函数，将原始时间序列作为规则采样.

In[14]:=

X regdata = TimeSeries[data, TemporalRegularity -> True]

Out[14]=

In[15]:=

X data["Path"] == regdata["Path"]

Out[15]=

In[16]:=

X RegularlySampledQ[regdata]

Out[16]=