逆メリン変換を求める: Wolfram言語 11の新機能

‹›

逆メリン変換を求める

InverseMellinTransformを使って逆メリン変換を計算する．

In[1]:=

InverseMellinTransform[Gamma[s], s, x]

Out[1]=

InverseMellinTransformによって想定される正則片を得る．

In[2]:=

InverseMellinTransform[Gamma[s], s, x, GenerateConditions -> True]

Out[2]=

BesselJを導く逆メリン変換を計算する．

In[3]:=

InverseMellinTransform[(2^(-1 + s) a^-s Gamma[1/2 + s/2])/
 Gamma[3/2 - s/2], s, x]

Out[3]=

の異なる値に対する結果をプロットする．

In[4]:=

InverseMellinTransform[(2^(-1 + s) a^-s Gamma[1/2 + s/2])/
 Gamma[3/2 - s/2], s, x];
Plot[Table[% , {a, 1, 5}] // Evaluate, {x, 0, 7}]

Out[4]=

基本的な逆メリン変換の表を生成する．

完全なWolfram言語入力を表示する

In[5]:=

flist = {1/s, 1/(s + 1), a^(s - 1), Gamma[s], 
  Gamma[1 - s], \[Pi] Csc[\[Pi] s], Gamma[s] Sin[(\[Pi] s)/2], 
  Cos[(\[Pi] s)/2] Gamma[s], \[Pi] Cot[\[Pi] s], 
  1/2 Gamma[s/2]}; TraditionalForm[
 Simplify[Grid[
   Map[Style[#, ScriptLevel -> 0] &, 
    Join[{{HoldForm@f[s], 
       HoldForm@InverseMellinTransform[f[s], s, x]}}, 
     Transpose[{flist, (InverseMellinTransform[#1, s, x] &) /@ 
        flist}]], {2}], Dividers -> All, Spacings -> {4, 2}, 
   Background -> {None, {{None, GrayLevel[.9]}}, {{1, 1} -> 
       Hue[.6, .4, 1], {1, 2} -> Hue[.6, .4, 1]}}, 
   BaseStyle -> {FontFamily -> Times, FontSize -> 13}]]]

Out[5]//TraditionalForm=