Wolfram Language

Geo Computation

GPS Receivers and Elevation

GPS receivers measure positions with respect to a reference oblate ellipsoid approximating the surface of the Earth. However, elevations with respect to the ellipsoid are not of direct practical use: for example, the elevation of the surface of a lake is not constant with respect to the ellipsoid. It needs to be converted to another reference surface, the geoid, which approximates mean sea level and continues it inland.

The elevation of the geoid with respect to the reference ellipsoid is called "undulation". Download undulation data in feet for the conterminous United States.

In[1]:=
Click for copyable input
undulation = GeoElevationData[Entity["Country", "UnitedStates"], "Undulation"]
Out[1]=

The geoid is always under the reference ellipsoid in the US area.

In[2]:=
Click for copyable input
MinMax[undulation]
Out[2]=

In particular, this is the undulation at Wolfram headquarters in Champaign, IL.

In[3]:=
Click for copyable input
GeoElevationData[ GeoPosition[ Entity["City", {"Champaign", "Illinois", "UnitedStates"}]], "Undulation"]
Out[3]=

Download data for the whole world.

In[4]:=
Click for copyable input
undulation = GeoElevationData["World", "Undulation"]
Out[4]=

Represent the data as a relief map.

In[5]:=
Click for copyable input
image = ReliefPlot[undulation, DataReversed -> True, PlotRangePadding -> None, PlotLegends -> Automatic, MaxPlotPoints -> Infinity, Frame -> False]
Out[5]=

Use a different geo projection.

In[6]:=
Click for copyable input
With[{bounds = {{-90, 90}, {-180, 180}}}, Legended[GeoGraphics[{GeoStyling[{"GeoImage", image[[1]]}, GeoRange -> bounds], GeoBoundsRegion[bounds]}, GeoRange -> bounds, GeoProjection -> "WinkelTripel", GeoGridLines -> True, ImageSize -> Medium], image[[2]]]]
Out[6]=

Related Examples

de es fr ja ko pt-br ru zh