Das Wetter in Chicago und europäischen Hauptstädten vergleichen: Neu in Wolfram Language 11

Das Wetter in Chicago und europäischen Hauptstädten vergleichen

Ermitteln Sie die EU-Hauptstadt, die im vergangenen Jahr ähnliche Temperaturen wie Chicago verzeichnet hat. Verwenden Sie die Funktion WarpingDistance, um die Ähnlichkeit zwischen Temperaturfolgen zu bestimmen.

In[1]:=

chicagoTemp = 
  WeatherData["Chicago", 
   "Temperature", {{2015, 7}, {2016, 6}, "Week"}, "Value"];

Rufen Sie die Temperaturen für alle Hauptstädte in der EU ab.

In[2]:=

capitals = CityData /@ CountryData["EU", "CapitalCity"] // Sort

Out[2]=

In[3]:=

capitalsTemp = 
  WeatherData[#, "Temperature", {{2015, 7}, {2016, 6}, "Week"}, 
      "Value"] -> # & /@ capitals;

Finden Sie die Hauptstadt, die die ähnlichsten Temperaturen zu Chicago verzeichnet.

In[4]:=

Nearest[capitalsTemp, chicagoTemp, 
 DistanceFunction -> (QuantityMagnitude@WarpingDistance[##] &)]

Out[4]=

Berechnen Sie paarweise Distanzen in einer Matrix.

In[5]:=

dm = DistanceMatrix[Keys@capitalsTemp, 
   DistanceFunction -> (QuantityMagnitude@WarpingDistance[##] &)];

Veranschaulichen Sie eine 7×7 Submatrix der Distanzmatrix.

In[6]:=

MatrixForm[Take[dm, 7, 7]]

Out[6]//MatrixForm=

Visualisieren Sie die Ähnlichkeit der Temperaturen anhand einer zuvor berechneten Distanzmatrix.

Den kompletten Wolfram Language-Input zeigen

In[7]:=

MatrixPlot[dm,
 FrameTicks -> {{Transpose[{Range[Length@capitals], capitals}], 
    None}, {Transpose[{Range[Length@capitals], 
      Rotate[#, \[Pi]/2] & /@ capitals}], None}}, Mesh -> True, 
 ColorFunction -> "BlueGreenYellow", 
 PlotLegends -> Placed[Automatic, Above], 
 PlotLabel -> "Distance based on temperature", ImageSize -> Large]

Out[7]=