Wolfram Language

Traitement d'images et de signaux

Comparez le climat à Chicago et les capitales européennes

Trouvez la ville de la capitale aux États-Unis qui a la température la proche de celle de Chicago l'an dernier. Utilisez WarpingDistance pour déterminer la similitude entre les séquences de température.

In[1]:=
Click for copyable input
chicagoTemp = WeatherData["Chicago", "Temperature", {{2015, 7}, {2016, 6}, "Week"}, "Value"];

Obtenez la température pour toutes les capitales de l'Union européenne.

In[2]:=
Click for copyable input
capitals = CityData /@ CountryData["EU", "CapitalCity"] // Sort
Out[2]=
In[3]:=
Click for copyable input
capitalsTemp = WeatherData[#, "Temperature", {{2015, 7}, {2016, 6}, "Week"}, "Value"] -> # & /@ capitals;

Trouvez la capitale ayant des températures les plus similaires à Chicago.

In[4]:=
Click for copyable input
Nearest[capitalsTemp, chicagoTemp, DistanceFunction -> (QuantityMagnitude@WarpingDistance[##] &)]
Out[4]=

Calculer les distances par paires dans une matrice.

In[5]:=
Click for copyable input
dm = DistanceMatrix[Keys@capitalsTemp, DistanceFunction -> (QuantityMagnitude@WarpingDistance[##] &)];

Montrez sous-matrice 7 * 7 de la matrice de distance.

In[6]:=
Click for copyable input
MatrixForm[Take[dm, 7, 7]]
Out[6]//MatrixForm=

Visualisez la température similaire en utilisant une matrice de distance précédemment calculée.

Montrer l'entrée complète de Wolfram Language
In[7]:=
Click for copyable input
MatrixPlot[dm, FrameTicks -> {{Transpose[{Range[Length@capitals], capitals}], None}, {Transpose[{Range[Length@capitals], Rotate[#, \[Pi]/2] & /@ capitals}], None}}, Mesh -> True, ColorFunction -> "BlueGreenYellow", PlotLegends -> Placed[Automatic, Above], PlotLabel -> "Distance based on temperature", ImageSize -> Large]
Out[7]=

Exemples connexes

de en es ja ko pt-br ru zh